BEGIN ISNFxIn

IF~Global("ISNFIntro","GLOBAL",0)~THEN BEGIN Introduction000
SAY @0 /* You do not belong in this place. Here the dead slumber in the restless drone of eternity, and you are neither dead nor restless. */
IF~~THEN REPLY @1 /* What do you mean? Is this an Astral Plane? */ GOTO Introduction001
IF~~THEN REPLY @2 /* I need answers to help me in my quest. Is this the...Underworld? */ GOTO Introduction002
END

IF~~THEN BEGIN Introduction001
SAY @3 /* This place? It is the shadow of death that exists at the end of every life, dark or bright. Is it the Astral Plane? I do not know. Is it real? Each individual must judge for himself. */
IF~~THEN GOTO Introduction003
END

IF~~THEN BEGIN Introduction002
SAY @4 /* Underworld? Yes. And no. */
= @5 /* You have courage. Demanding answers, even while you stand on the most glorious and fatal of thresholds. */
IF~~THEN GOTO Introduction003
END

IF~~THEN BEGIN Introduction003
SAY @6 /* This place is shaped by wishes, dreams and memories. This place is alive so do not underestimate it. Our land shall show the truth to the one who opens the door. But--I can tell you're not the one. Interesting. I think it happens for the first time. */
= @7 /* (with temporary absence in the eyes) Since you made your introduction, it will happen again, and maybe--maybe never again. More than that... more than that... */
= @8 /* (shakes head with confusion) I'm sorry, I just... lost my thread of thought. */
= @9 /* Tell me what you seek, and I may be able to give you some answers. I cannot read the hearts and minds of mortal beings, but my vision does extend beyond yours in other ways. We are oracles unbound by life! */
IF~~THEN REPLY @10 /* I was sent to find one woman - Selene Root. Do you know her? */ GOTO Introduction004
IF~~THEN REPLY @11 /* My business here is still my business. You don't need to know anything more than that, creature. Get out of my way. */ GOTO Introduction005
IF~~THEN REPLY @12 /* Yes, you're right. I'm sorry. I am a bit nervous. This place seems to be so...different. */ GOTO Introduction006
END

IF~~THEN BEGIN Introduction006
SAY @13 /* Worry not. You will find that such sentiments are quite trivial here. What is the reason behind your presence? */
IF~~THEN REPLY @14 /* Well, I was sent to find one woman - Selene Root. Have you heard the name? */ GOTO Introduction004
IF~~THEN REPLY @15 /* That is my business. You don't need to know a single thing, creature. Get out of my way. */ GOTO Introduction005
END

IF~~THEN BEGIN Introduction004
SAY @16 /* Names mean nothing here, for in death, we are all equal. We are one. And we are nothing. */
= @17 /* But if the name means something to you... Can you see this pit? The name will guide you. It's like a string. As I said, this world is smart, it shapes itself, and that which inhabits it to serve the purpose of those who enter it. No, it's more, yet difficult to describe; to understand. But just trust this place. */
= @18 /* You will see memories and become an actor yourself. You will know what to say, if you listen to your thoughts. You will just know. It may be a better idea to follow the threads pulled from your thoughts than to resort to sword and fist. As I said - trust. */
= @19 /* Keep in mind this does not mean obliviousness. Be wary of the shades. They are blind souls; nightmares that dwell here, in this world. The restlessness of this realm is not to be doubted. */
IF~~THEN REPLY @20 /* I'm not afraid of anything. */ GOTO Introduction007
IF~~THEN REPLY @21 /* Thank you for your warning. */ GOTO Introduction008
IF~~THEN REPLY @22 /* Will you come with me? I may need some help. */ GOTO Introduction009
END

IF~~THEN BEGIN Introduction007
SAY @23 /* Courage in this place is the veil between life and death. It will serve you well. */
IF~~THEN GOTO Introduction010
END

IF~~THEN BEGIN Introduction008
SAY @24 /* Wield this knowledge as a shield. */ 
IF~~THEN GOTO Introduction010
END

IF~~THEN BEGIN Introduction009
SAY @25 /* No. I belong to the upper side. To follow the threads of your thoughts, you will need to go down that tunnel. */
IF~~THEN GOTO Introduction010
END

IF~~THEN BEGIN Introduction010
SAY @26 /* So go, if you must. My presence is required elsewhere. */
IF~~THEN REPLY @27 /* Farewell. Thank you for your help. */ GOTO Introduction011
IF~~THEN REPLY @28 /* Leave then. I know everything I wanted to know. */ GOTO Introduction011
IF~~THEN REPLY @29 /* Wait! What if--I didn't open the door. Does it mean I may find more than Selene--? */ GOTO Introduction012
IF~~THEN REPLY @30 /* Wait! Is it possible to take one of your kind from this realm? */ GOTO Introduction012
IF~~THEN REPLY @31 /* Wait! How can I fight the creatures that live in there? */ GOTO Introduction012
IF~~THEN REPLY @32 /* Wait a second. I want to know more. I seek power! */ GOTO Introduction012
END

IF~~THEN BEGIN Introduction011
SAY @33 /* Fare you well. */
IF~~THEN DO ~SetGlobal("ISNFIntro","GLOBAL",1) EscapeArea()~ EXIT
END

IF~~THEN BEGIN Introduction005
SAY @34 /* Good luck. */
IF~~THEN DO ~SetGlobal("ISNFIntro","GLOBAL",1) EscapeArea()~ EXIT
END

IF~~THEN BEGIN Introduction012
SAY @35 /* (Ignores you and walks away; with every step the spectre trembles more and more, when suddenly is cracks and disappears.) */
IF~~THEN DO ~SetGlobal("ISNFIntro","GLOBAL",1) EscapeArea()~ EXIT
END

