BEGIN ISNFxSe

IF~Global("ISNFQuest","GLOBAL",9)~THEN BEGIN Selene000
SAY @0 /* You shouldn't be here, Child of Bhaal. No--no matter how much I want you to be here, I just... */
IF~~THEN REPLY @1 /* Uh, do I have "Child of Bhaal" written on my forehead or something? */ GOTO Selene001
IF~~THEN REPLY @2 /* And you are...? */ GOTO Selene001
IF~~THEN REPLY @3 /* Oh great. I think I already hate this place. I have a bad feeling. */ GOTO Selene001
END

IF~~THEN BEGIN Selene001
SAY @4 /* I am Selene. The one you're looking for, but as you can see, I cannot be reached... Even by you... (Even through the distance separating you and Selene, you can see her eyes are welling with tears; becoming like water mirrors) */
IF~~THEN REPLY @5 /* Orion prepared everything for your come back, Selene. */ GOTO Selene00X1
IF~~THEN REPLY @6 /* Don't tell me all this was just a waste of time. */ GOTO Selene00X1
END

IF~~THEN BEGIN Selene00X1
SAY @7 /* It--it has been something very different... */
= @8 /* ...did he suffer? Did he suffer all this time since I left? */
IF~~THEN REPLY @9 /* Yes. */ GOTO Selene00X2
IF~~THEN REPLY @10 /* He didn't just suffer. He is dying of despair, Selene. I can't go back and tell him that you can't leave the Underworld. */ GOTO Selene00X2
END

IF~~THEN BEGIN Selene00X2
SAY @11 /* All these noises and shadows... yet, I do belong to this divine world of death... No matter how much we struggle, we change and... and we turn into something very different. I have already changed, already, but... I still remember him. I remember my dear Orion. */
= @12 /* But you know that. You've seen our memories, our...our moments. Some were sweet; some were bitter, but all of them are real. They became engraved in my very own world. In my Echo. My Echo you reached because he opened the door... */
IF~Global("ISNFGorionMemory","GLOBAL",1)~THEN REPLY @13 /* Your Echo--but I've seen Gorion! I've talked to my foster father. */ GOTO Selene00X3
IF~~THEN REPLY @14 /* He opened the door for you, Selene. */ GOTO Selene00X4
IF~~THEN REPLY @15 /* Echo? I don't care how you call this place. There's no Orion here. Do you really wish to stay? */ GOTO Selene00X4
IF~~THEN REPLY @16 /* This isn't fair. */ GOTO Selene00X4
END

IF~~THEN BEGIN Selene00X3
SAY @17 /* I knew something changed... */
= @18 /* ...I'm sorry, but that was just one memory. Different, though, and I hope you'll remember it. Treasure it. */
IF~~THEN GOTO Selene00X4
END

IF~~THEN BEGIN Selene00X4
SAY @19 /* ... */
= @20 /* Orion... I have no idea what I should feel - on one hand, he broke the rule; he tried to change the Color of Everything that Happened and Color of the Unchangeable. But on the other hand...he did all this for me. */
= @21 /* It feels so strange. */
= @22 /* It feels as if I were--a flower that has died, but on the day of its death, spilled its seeds into the ground. A different ground, that shall become his, but not...not yet... */
= @23 /* ...soon, though... (she cries) */
= @24 /* ...I know... */
IF~~THEN REPLY @25 /* You have been watching your husband then? */ GOTO Selene002
IF~~THEN REPLY @26 /* I am here because I must fulfill my duty. I must do this. Don't you understand? */ GOTO Selene002
END

IF~~THEN BEGIN Selene002
SAY @9 /* Yes. */
= @27 /* I know what you would say, Child of Bhaal, but I am unreachable, I can just watch. Can you see the void? Look around me - I'm being protected by this world. This dark, yet warm and kind place. That... */
= @28 /* That... */
= @29 /* You're just giving me more pain. I felt cold, but once you came here; once he broke the rules for me...I felt different. */
= @30 /* We are all dead here, but this death of ours isn't as black as they would lead you to believe. It's as purple as magic itself. As wishes that can never be fulfilled. As a thought that could crush a stone. Now you added something more...something that reversed the smell, the taste... */
IF~~THEN REPLY @31 /* I want to ask in order to know your final answer: was all of this for nothing? */ GOTO Selene003
IF~~THEN REPLY @32 /* Can't you do anything? If this place is a part of you, then you should be able to leave it! Or shape it! I'm sure you can. */ GOTO Selene003
IF~~THEN REPLY @33 /* Shall I return with empty hands then? */ GOTO Selene003
END

IF~~THEN BEGIN Selene003
SAY @19 /* ... */
= @34 /* Nothing can be done, but... tell him that he still holds my heart. We shall be together soon. I count every passing hour until that time comes... */
= @35 /* I'm sorry, but I can say no more... (cries and suddenly everything fades away) */
IF~~THEN DO ~SetGlobal("ISNFQuest","GLOBAL",10) FadeToColor([20.0],0) ActionOverride(Player1,LeaveAreaLUA("ISNF01","",[500.300],4)) FadeFromColor([20.0],0) CreateVisualEffectObject("SPPORTAL",Player1)~ EXIT
END
