BEGIN ISNFxN

//1

CHAIN IF~Global("ISNFMakeEnemy","GLOBAL",0)~THEN ISNFxN Ganymedes000
@0 /* So the rumors are true, then. Orion has found himself a new lackey. */
==NaliaJ IF ~InParty("Nalia") !StateCheck("Nalia",CD_STATE_NOTVALID)~ THEN @1 /* What does he mean by that? */
==AnomenJ IF ~InParty("Anomen") !StateCheck("Anomen",CD_STATE_NOTVALID)~ THEN @2 /* Lackey? Explain yourself! */
END
IF~~THEN REPLY @3 /* Hmph. And you are...? */ EXTERN ISNFxN Ganymedes001
IF~~THEN REPLY @4 /* Indeed. His intentions are pure. He wants to see his wife again. */ EXTERN ISNFxN Ganymedes002

APPEND ISNFxN

IF~~THEN BEGIN Ganymedes001
SAY @5 /* I am Ganymedes, but somehow I doubt my name would tell you anything. */
= @6 /* I am Selene's brother. */
IF~~THEN GOTO Ganymedes003
END

IF~~THEN BEGIN Ganymedes002
SAY @7 /* Pure? He loves her but... */
=
@8 /* Eh, I suppose I should give you my name first, before we'll continue our discussion. I am Ganymedes. Selene's brother. */
IF~~THEN GOTO Ganymedes003
END

IF~~THEN BEGIN Ganymedes003
SAY @9 /* Do you really think he can succeed in bringing my sister back? Gods, I'm not sure if I want to know the answer, but--I just can't stop myself from wondering if...if that's possible at all. */
IF~~THEN REPLY @10 /* We don't know yet, Ganymedes. But you don't seem really happy that he's still working on bringing Selene back to life. */ GOTO Ganymedes004
IF~~THEN REPLY @11 /* I believe in Orion. I am sure he can do it, but he needs some support. It seems he didn't get any of it from his wife's family. */ GOTO Ganymedes004
IF~~THEN REPLY @12 /* No, I don't think so, but I know he must try. If he just sat down and cried, he would be disgusted with himself later. */ GOTO Ganymedes005
IF~~THEN REPLY @13 /* I have no time for this talking. Let us move on. */ GOTO Ganymedes006
END

IF~~THEN BEGIN Ganymedes004
SAY @14 /* You just don't understand. */
IF~~THEN GOTO Ganymedes0007
END

IF~~THEN BEGIN Ganymedes005
SAY @15 /* Maybe. Maybe it would have had less dangerous consequences than his current endeavors. */
IF~~THEN GOTO Ganymedes0007
END

IF~~THEN BEGIN Ganymedes0007
SAY @16 /* But I'm not sure if that's a good idea to talk about this in the middle of a street. */
IF~~THEN REPLY @17 /* Why so? */ GOTO Ganymedes008
IF~~THEN REPLY @18 /* If you say so. */ GOTO Ganymedes009
IF~~THEN REPLY @19 /* I don't feel like talking to you at all. Begone! */ GOTO Ganymedes006
END

IF~~THEN BEGIN Ganymedes008
SAY @20 /* We may drag attention and I am sure Orion wouldn't appreciate this. He's quite lucky already that Cowled Wizards have no idea about his studies. */
IF~~THEN GOTO Ganymedes009
END

IF~~THEN BEGIN Ganymedes009
SAY @21 /* Shall we meet at a later time and in a different place? */
IF~~THEN REPLY @22 /* I suppose there's no harm in hearing what you have to say. */ GOTO Ganymedes007
IF~~THEN REPLY @23 /* I am not interested. Now leave me be. */ GOTO Ganymedes006
END

IF~~THEN BEGIN Ganymedes007
SAY @24 /* Thank you. And forgive my confusion. This whole matter is rather delicate and--I hope you understand. */
=
@25 /* Meet me at the Docks. I shall wait for you in my house next to the barracks. It is the building which looks like a kind of gate. */
IF~~THEN DO ~SetGlobal("ISNFMakeEnemy","GLOBAL",1) EscapeArea()~ EXIT
END

IF~~THEN BEGIN Ganymedes006
SAY @26 /* A pity then. I just hope you won't end up like Selene or the - so-called - "Incomplete." */
IF~~THEN DO ~SetGlobal("ISNFMakeEnemy","GLOBAL",10) EscapeArea()~ EXIT
END


//2

IF~Global("ISNFMakeEnemy","GLOBAL",1) AreaCheck("AR0416")~THEN BEGIN Ganymedes200
SAY @27 /* Ah, it's you. I'm glad you found my house and that you came at all. I know the first impression I must have made wasn't really...fortunate. I still don't believe that Selene is gone and--I'm just not sure who I should blame. */
IF~~THEN REPLY @28 /* I understand. So, what would you like me to know? */ GOTO Ganymedes201
IF~~THEN REPLY @29 /* It's fine. I've seen worse introductions. */ GOTO Ganymedes202
IF~~THEN REPLY @30 /* You should be sorry. Calling someone a "lackey" - that's not very nice. */ GOTO Ganymedes203
END

IF~~THEN BEGIN Ganymedes202
SAY @31 /* Thank you. */
IF~~THEN GOTO Ganymedes201
END

IF~~THEN BEGIN Ganymedes203
SAY @32 /* Again - I apologize. I shouldn't have... */
IF~~THEN GOTO Ganymedes201
END

IF~~THEN BEGIN Ganymedes201
SAY @33 /* I asked you to come both to get some answers from you and to tell everything you would like to know about Orion and the circumstances of...of our loss. */
IF~~THEN REPLY @34 /* I'm glad. Sometimes it's really hard to get details from Orion. He's both secretive and he can't focus on anything other than work. */ GOTO Ganymedes204
IF~~THEN REPLY @35 /* I'm eager to cooperate. It must have been a shock to you, too, and you deserve to know what's going on. */ DO ~ReputationInc(1)~ GOTO Ganymedes205
IF~~THEN REPLY @36 /* I thought you could tell me something more...significant than answer some stupid questions. I don't give a thing about your "family stories". Farewell. */ GOTO Ganymedes206
END

IF~~THEN BEGIN Ganymedes204
SAY @37 /* He's always been like that. When he starts to work, everything outside his laboratory becomes "irrelevant". */
IF~~THEN GOTO Ganymedes207
END

IF~~THEN BEGIN Ganymedes205
SAY @38 /* I--thank you. You seem nicer than I have thought. */
IF~~THEN GOTO Ganymedes207
END

IF~~THEN BEGIN Ganymedes207
SAY @39 /* Well, let me ask the first question. Do you REALLY think that he can actually bring her back? I know I have already asked you those questions, but... I'm not sure what I should think. */
IF~~THEN REPLY @40 /* Orion is doing what he can. I have no idea if he can bring her back, but that's beyond my comprehension. There are some matters only he can understand, I suppose. */ GOTO Ganymedes208
IF~~THEN REPLY @41 /* I...I don't think so. That's just impossible. If anyone could be brought back, then Faerun would be as crowded as Nine Hells, I guess. */ GOTO Ganymedes208
IF~~THEN REPLY @42 /* Yes. I think it's possible. As someone have once said: "There are no impossible situations, just people who give up too soon". */ GOTO Ganymedes208
IF~~THEN REPLY @43 /* I have no idea and I don't want to know. I thought you would tell me something more useful. But whatever. I should be leaving. */ GOTO Ganymedes206
END

IF~~THEN BEGIN Ganymedes208
SAY @44 /* I see. Thank you for telling me. Maybe that will grant me some peace of mind, allow me to understand the situation better. */
= @45 /* There is something more I would like to know, and please - be honest with me. */
= @46 /* Orion is excessively dedicated to everything he does. Now, when it's about my sister, whom he loved more than anything else, I am afraid he may decide--he may decide to go too far. And I suppose there are some limits no one should ever challenge... but maybe now. Oh, I just don't know. */
IF~~THEN REPLY @47 /* Orion may be dangerous but I won't let him make this tragedy even worse. I can always stop him, when necessary. */ GOTO Ganymedes209
IF~~THEN REPLY @48 /* I don't think he can go too far. He knows what love means, and someone who felt it, can't be evil. */ GOTO Ganymedes210
IF~~THEN REPLY @49 /* I'm not sure what to tell you. But know that I'll be there to make sure he's no threat to innocent civilians. I'd rather kill him. */ GOTO Ganymedes211
IF~~THEN REPLY @50 /* Whatever. I thought our talk would be more...significant. I'm leaving. */ GOTO Ganymedes206
END

IF~~THEN BEGIN Ganymedes209
SAY @51 /* I see. That's good. There should be someone like you - a pair of brakes that can stop him if he goes too far... I think... */
IF~~THEN GOTO Ganymedes212
END

IF~~THEN BEGIN Ganymedes210
SAY @52 /* Maybe you're right, but...what if he becomes blind; if he start to hurt innocents...? I just hope it won't end like that. */
IF~~THEN GOTO Ganymedes212
END

IF~~THEN BEGIN Ganymedes211
SAY @53 /* I--I see... */
IF~~THEN GOTO Ganymedes212
END

IF~~THEN BEGIN Ganymedes212
SAY @54 /* Anyway, I promised to answer some of your questions. */
IF~~THEN GOTO Ganymedes21Q0
END

IF~~THEN BEGIN Ganymedes21Q0
SAY @55 /* What else would you like to know? */
IF~OR(2) Global("GaniQ1","LOCALS",0) Global("GaniQ1","LOCALS",1)~THEN REPLY @56 /* Tell me how all this started. I would like to know your version of the story. */ DO ~SetGlobal("GaniQ1","LOCALS",1)~ GOTO Ganymedes21Q1
IF~OR(2) Global("GaniQ2","LOCALS",0) Global("GaniQ2","LOCALS",1)~THEN REPLY @57 /* If you were to blame just one person, who that would be? */  DO ~SetGlobal("GaniQ2","LOCALS",1)~ GOTO Ganymedes21Q2
IF~OR(2) Global("GaniQ3","LOCALS",0) Global("GaniQ3","LOCALS",1)~THEN REPLY @58 /* Do you think that Orion would want to hurt someone to get Selene back? */  DO ~SetGlobal("GaniQ3","LOCALS",1)~ GOTO Ganymedes21Q3
IF~OR(2) Global("GaniQ4","LOCALS",0) Global("GaniQ4","LOCALS",1)~THEN REPLY @59 /* Why won't you talk to him on your own? */  DO ~SetGlobal("GaniQ4","LOCALS",1)~ GOTO Ganymedes21Q4
IF~OR(2) Global("GaniQ5","LOCALS",0) Global("GaniQ5","LOCALS",1)~THEN REPLY @60 /* If you were in my shoes, would you help Orion? */  DO ~SetGlobal("GaniQ5","LOCALS",1)~ GOTO Ganymedes21Q5
IF~CheckStatGT(Player1,13,INT) Global("GaniQ1","LOCALS",1) Global("GaniQ2","LOCALS",1) Global("GaniQ3","LOCALS",1) Global("GaniQ4","LOCALS",1) Global("GaniQ5","LOCALS",1) Global("GaniQ6","LOCALS",0)~THEN REPLY @61 /* I have one final question - I can see how nervous you are. There must be something more. */ DO ~SetGlobal("GaniQ6","LOCALS",1) AddexperienceParty(200)~ GOTO Ganymedes21Q6
IF~~THEN REPLY @62 /* I don't have any questions. Goodbye. */ GOTO Ganymedes21E
END

IF~~THEN BEGIN Ganymedes21Q1
SAY @63 /* As you wish. I shall start with... with my first impression. */
=@64 /* In the beginning, I thought Orion was a good man. Then I realized his tendency to gamble away anything and everything for the sake of his research. */
= @65 /* My sister Selene truly loved him, however, and it pained her to watch him take such risks. One day, he told her he needed to leave for a few weeks to uncover some old arcane lore he planned to add to his library. She asked to accompany him on his journey and he agreed. */
= @66 /* He let her follow him. I hated him. */
= @67 /* But when it was over. When--when she left us, I could see his despair. It was almost material. And then I thought... that maybe I was too harsh. I don't know. */
IF~~THEN GOTO Ganymedes21Q0
END

IF~~THEN BEGIN Ganymedes21Q2
SAY @68 /* I... */
= @69 /* We can all be blamed. He let her go. Orion paid more attention to the research than-- */
= @70 /* But on the other hand Selene wanted to go. It was her own decision. */
= @71 /* The Incomplete... it's hard to judge someone who in the end lost his humanity. */
= @72 /* And me - someone who should have been there, who could have assisted them. */
= @73 /* I can't blame just one person. */
IF~~THEN GOTO Ganymedes21Q0
END

IF~~THEN BEGIN Ganymedes21Q3
SAY @74 /* I don't know. Probably. But I find it difficult to make him stop. That's why he needs someone sane beat his side. I hope you're levelheaded enough to become a proper support. */
IF~~THEN GOTO Ganymedes21Q0
END

IF~~THEN BEGIN Ganymedes21Q4
SAY @75 /* There is more than one reason. */
= @76 /* First of all, we would shout at each other over and over. Our relations are... rather tense. Even when she was here... we would just end up fighting. */
= @77 /* Secondly, I just cannot decide what should be done. I want Selene back, but--what if others must suffer in order to bring her from the dead? */
= @78 /* That's why I'm glad I could talk to you. */
IF~~THEN GOTO Ganymedes21Q0
END

IF~~THEN BEGIN Ganymedes21Q5
SAY @79 /* I don't know.... I... just don't know. I'm sorry, but it's too complicated. */
IF~~THEN GOTO Ganymedes21Q0
END

IF~~THEN BEGIN Ganymedes21Q6
SAY @80 /* You're a skilled adventurer... */
= @81 /* I set some false clues as I didn't want Cowled Wizards to find out about his researches. You should be free to act, for now. But... */
IF~~THEN GOTO Ganymedes21E
END

IF~~THEN BEGIN Ganymedes21E
SAY @82 /* ...I will leave Athkatla. I don't want to be here; this isn't my affair anymore. I leave all this to Orion. He still loves my sister. You're here, too. */
= @83 /* So farewell. Everything's up to you two. */
IF~~THEN DO ~SetGlobal("ISNFMakeEnemy","GLOBAL",2) EscapeArea()~ EXIT
END

IF~~THEN BEGIN Ganymedes206
SAY @84 /* Farewell. */
IF~~THEN DO ~SetGlobal("ISNFMakeEnemy","GLOBAL",2) EscapeArea()~ EXIT
END
END
