BEGIN ISNFxO2

IF~Global("ISNFExtraInn","GLOBAL",0)~THEN BEGIN InnOrion000
SAY @0 /* So--so you're here. */
= @1 /* I can't believe how you managed to make me come here. It feels a bit off, somehow. */
IF~~THEN REPLY @2 /* You just had to leave the laboratory, otherwise you may lose your mind. You don't want that to happen, right? */ GOTO InnOrion001
IF~~THEN REPLY @3 /* It must be this mice magic. Someone once told me that with it I can make people do things, heh. */ GOTO InnOrion002
END

IF~~THEN BEGIN InnOrion001
SAY @4 /* Eh, I think I lost it already, some time ago. */
IF~~THEN GOTO InnOrion003
END

IF~~THEN BEGIN InnOrion002
SAY @5 /* Mice magic you say... */
IF~~THEN GOTO InnOrion003
END

IF~~THEN BEGIN InnOrion003
SAY @6 /* Well, I must say that this place has changed a bit, it was more... unique. Now it looks like every other inn in Athkatla. */
IF~~THEN REPLY @7 /* What would you like to have? Wine? Beer? */ GOTO InnOrion004
IF~~THEN REPLY @8 /* I must say that I was rather surprised that you wanted to meet in here, while the Five Flagons alehouse is just around the corner. */ GOTO InnOrion005
IF~~THEN REPLY @9 /* Are you all right? */ GOTO InnOrion006
END

IF~~THEN BEGIN InnOrion004
SAY @10 /* Wine. I'll take Sunbreath Wine. */
IF~~THEN GOTO InnOrion007
END

IF~~THEN BEGIN InnOrion005
SAY @11 /* You can call it 'nostalgia'. */
IF~~THEN GOTO InnOrion007
END

IF~~THEN BEGIN InnOrion006
SAY @12 /* Yes, sorry. I was just... thinking. */
IF~~THEN GOTO InnOrion007
END

IF~~THEN BEGIN InnOrion007
SAY @13 /* If there was any place I could meet with you, it would be here. The place I've visited with Selene long time ago, just after we met for the first time. Heh. */
IF~~THEN REPLY @14 /* Heh, I knew it. */ GOTO InnOrion008
IF~~THEN REPLY @15 /* Here? But there are so many places you could visit and even so you decided to come here? You really are strange, you know. */ GOTO InnOrion008
IF~~THEN REPLY @16 /* Oh, not that again... Sorry, but I'm not in the mood for that. */ GOTO InnOrion009
END

IF~~THEN BEGIN InnOrion008
SAY @17 /* I would like to tell you how we met for the first time. */
IF~~THEN REPLY @18 /* Sure. I'm all ears. */ GOTO InnOrion010
IF~~THEN REPLY @19 /* Better spend this time on your own. I'm not in the mood for this. Goodbye. */ GOTO InnOrion009
END

IF~~THEN BEGIN InnOrion010
SAY @20 /* Thank you. */
= @21 /* You know, we've met for the first time in the theatre in the basement of Five Flagons. I was to watch the actors who were presenting "The Marvelous Journey of Count Sack", but I just couldn't look at them while she was sitting two seats away from me. */ 
= @22 /* Heh, I would rather see her smile and laugh than a group of men say their lines. */
IF~~THEN REPLY @23 /* Oh, she already got you. */ GOTO InnOrion011
IF~~THEN REPLY @24 /* Mhm, continue. */ GOTO InnOrion011
END

IF~~THEN BEGIN InnOrion011
SAY @25 /* When the show was over, I decided to ask if she’d enjoyed the play. She was eager to talk but then--then we realized that there are no free tables in the inn! So we left and looked for the nearest place where we could talk. */
= @26 /* That's how we found this place. It was newly opened so only few people knew of it. You could even smell the freshly cut wood they used. */
= @27 /* We talked for five hours. I didn't even know that I could talk for such a long time. It was worth it. We met again two days later. */
= @28 /* Then again...and again. */
IF~~THEN REPLY @29 /* It's a really lovely story. */ GOTO InnOrion012
IF~~THEN REPLY @30 /* And one day you two stayed together. */ GOTO InnOrion013
IF~~THEN REPLY @31 /* Sorry, but it sounds really ordinary. Nothing special. */ GOTO InnOrion014
END

IF~~THEN BEGIN InnOrion012
SAY @32 /* It would be lovely if not for the present circumstances... */
IF~~THEN GOTO InnOrion015
END

IF~~THEN BEGIN InnOrion013
SAY @33 /* Until her death, yes. */
= @34 /* But actually even now I feel as if she is watching over me; as if she wants to tell me something. One day I found her favorite flower on my desk. I just want to believe she brought it. */
IF~~THEN GOTO InnOrion015
END

IF~~THEN BEGIN InnOrion014
SAY @35 /* It's a common knowledge that extraordinary adventures start with very ordinary happenings. */
IF~~THEN GOTO InnOrion015
END

IF~~THEN BEGIN InnOrion015
SAY @36 /* Huh, I hope I didn't bore you to death. I think I should leave now as I don't feel very well. I'm so tired and--I think I need some sleep. */
IF~~THEN REPLY @37 /* It's because of your work. */ GOTO InnOrion016
IF~~THEN REPLY @38 /* Everything will be over soon, Orion. */ GOTO InnOrion017
IF~~THEN REPLY @39 /* Go and have a rest, then. */ GOTO InnOrion018
END

IF~~THEN BEGIN InnOrion016
SAY @40 /* I guess you're right. */
= @41 /* Thank you for the time you offered me. Really. */
IF~~THEN DO ~SetGlobal("ISNFExtraInn","GLOBAL",1) AddexperienceParty(1000) EscapeArea()~ EXIT
END

IF~~THEN BEGIN InnOrion017
SAY @42 /* Yes...you may be right. */
= @43 /* Thank you for this talk. We'll meet in my laboratory soon. */
IF~~THEN DO ~SetGlobal("ISNFExtraInn","GLOBAL",1) AddexperienceParty(1000) EscapeArea()~ EXIT
END

IF~~THEN BEGIN InnOrion018
SAY @44 /* I will. */
= @20 /* Thank you. */
IF~~THEN DO ~SetGlobal("ISNFExtraInn","GLOBAL",1) AddexperienceParty(1000) EscapeArea()~ EXIT
END

IF~~THEN BEGIN InnOrion009
SAY @45 /* I'll stay here alone, then. */
IF~~THEN DO ~SetGlobal("ISNFExtraInn","GLOBAL",1) EscapeArea()~ EXIT
END
