BEGIN ISNFxA

IF~True()~THEN BEGIN Artist000
SAY @0 /* You don't look like someone interested in ordering a piece of art. Sorry if I seem rude, but I'm really very busy at the moment. */
IF~Global("ISNFQuest","GLOBAL",6)~THEN REPLY @1 /* Actually, could you make me a sculpture? It's quite urgent. */ GOTO Artist001
IF~~THEN REPLY @2 /* Well, you're right. Farewell. */ GOTO Artist003
IF~~THEN REPLY @3 /* Do you perhaps have other useful things for sale? */ GOTO Artist002
END

IF~~THEN BEGIN Artist002
SAY @4 /* Sorry, but I'm not one of those weapon traders. I'm an artist. */
IF~Global("ISNFQuest","GLOBAL",6)~THEN REPLY @5 /* Could you make me a sculpture, then? It's quite urgent. */ GOTO Artist001
IF~~THEN REPLY @6 /* So I see. I'll be off then. */ GOTO Artist003
END

IF~~THEN BEGIN Artist001
SAY @7 /* Ah, so we actually can do some business. Tell me, what should the sculpture look like? */
IF~~THEN REPLY @8 /* A man named Orion would like you to make a sculpture of his dead wife. Here's the portrait of her. */ GOTO Artist004
IF~~THEN REPLY @9 /* I'm here on behalf of a man who needs a sculpture of the woman in this drawing. */ GOTO Artist004
END

IF~~THEN BEGIN Artist004
SAY @10 /* Hmm, let me take a look... */
= @11 /* I think I can do it, but I'd like to talk to the employer. Where does he live? */
IF~~THEN REPLY @12 /* He lives near the prison in the Government District. */ GOTO Artist005
IF~~THEN REPLY @13 /* You can find him in the Government District. Ask a city guard and I'm sure he'll be able to point you in the right direction. */ GOTO Artist005
IF~~THEN REPLY @14 /* I can take you to his home right now, if you like. */ GOTO Artist006
END

IF~~THEN BEGIN Artist005
SAY @15 /* I will go and look for him, then. */
IF~~THEN DO ~SetGlobal("ISNFQuest","GLOBAL",7) EscapeArea()~ EXIT
END

IF~~THEN BEGIN Artist006
SAY @16 /* Splendid! */
IF~~THEN DO ~FadeToColor([20.0],0)
SetGlobal("ISNFQuest","GLOBAL",7)
ActionOverride(Player1,LeaveAreaLUA("ISNF01","",[500.300],4))
ActionOverride(Player2,LeaveAreaLUA("ISNF01","",[505.300],4))
ActionOverride(Player3,LeaveAreaLUA("ISNF01","",[500.305],4))
ActionOverride(Player4,LeaveAreaLUA("ISNF01","",[505.305],4))
ActionOverride(Player5,LeaveAreaLUA("ISNF01","",[510.305],4))
ActionOverride(Player6,LeaveAreaLUA("ISNF01","",[505.310],4))
FadeFromColor([20.0],0)
EscapeArea()~ EXIT
END

IF~~THEN BEGIN Artist003
SAY @17 /* Goodbye. */
IF~~THEN EXIT
END