BEGIN ISNFxRE

IF~Global("ISNFBirdEncounter","GLOBAL",2)~THEN BEGIN Reward000
SAY @0 /* Welcome. */
IF~~THEN REPLY @1 /* Uhm, who are you? */ GOTO Reward003
IF~~THEN REPLY @2 /* Hello. Sorry, I didn't know you're here. */ GOTO Reward001
IF~~THEN REPLY @3 /* Greetings. */ GOTO Reward002
END

IF~~THEN BEGIN Reward001
SAY @4 /* It's fine. I'm used to that kind of attitude. But--I suppose you are a bit surprised that someone just appeared out of the blue. */
IF~~THEN GOTO Reward003
END

IF~~THEN BEGIN Reward002
SAY @5 /* Hmm, interesting. I thought you would be more surprised when someone just appears out of the blue. Anyway, I suppose I should tell you who I am. */
IF~~THEN GOTO Reward003
END

IF~~THEN BEGIN Reward003
SAY @6 /* You may not recognise me, although we've met before. But I looked different. You saved me, as I was kept in a... prison. Even though, you let me go. If it weren't for of you, I would be still there. Even now. */
IF~~THEN REPLY @7 /* Funny. I think I would remember something like that. */ GOTO Reward004
IF~~THEN REPLY @8 /* I always remember people I save. And I think I know what you're talking about-- */ GOTO Reward005
IF~~THEN REPLY @9 /* You know, I meet A LOT of people, so mind me but I haven't got a clue who you are. */ GOTO Reward006
END

IF~~THEN BEGIN Reward004
SAY @10 /* Just trust me: you have met me and let me go. */
IF~~THEN GOTO Reward007
END

IF~~THEN BEGIN Reward005
SAY @11 /* --no need to talk about this. It was rather embarrassing. I wasn't in my best... shape. */
IF~~THEN GOTO Reward007
END

IF~~THEN BEGIN Reward006
SAY @12 /* That's fine. */
IF~~THEN GOTO Reward007
END

IF~~THEN BEGIN Reward007
SAY @13 /* I'm not here to make you remember, nor to say "hello", but rather to say "thank you". My unfortunate situation has changed thanks to the aid you offered me. */
IF~~THEN REPLY @14 /* There's no need to thank me. Really. */ GOTO Reward008
IF~~THEN REPLY @15 /* You are welcome. */ GOTO Reward008
IF~~THEN REPLY @16 /* Thank you? And that's all? */ GOTO Reward008
END

IF~~THEN BEGIN Reward008
SAY @17 /* It's not just about the words, but also about deeds and debts. That's why I would like to give you something. I'm not very rich, but I think I've got something you may use. */
= @18 /* Here, take this scroll. It's not much, but--but still better than nothing. I would give you more, if I had more than that. */
IF~~THEN REPLY @19 /* Thank you. That's very kind. */ GOTO Reward009
IF~~THEN REPLY @20 /* I should get more than an old parchment. */ GOTO Reward010
END

IF~~THEN BEGIN Reward009
SAY @21 /* It is I who thank you, adventurer. */
IF~~THEN GOTO Reward011
END

IF~~THEN BEGIN Reward010
SAY @22 /* It's not JUST parchment. */
IF~~THEN GOTO Reward011
END

IF~~THEN BEGIN Reward011
SAY @23 /* Anyway, I need to leave. There are some things that need to be fetched and some people I should talk to. It's been four years since I became a prisoner. */
= @24 /* Just a few more words of advice: be careful, adventurer. I have a feeling that something awaits you. There are more shadows in the corners when you're close. That why you need to remember who can be trusted, and who should be observed. */
= @25 /* Farewell. */
IF~~THEN DO ~SetGlobal("ISNFBirdEncounter","GLOBAL",3) GiveItemCreate("ISNFxRE",Player1,0,0,0) DestroySelf()~ EXIT
END
