BEGIN ISNFxOr

//Telescope

IF~Global("ISNFObject1Talk","GLOBAL",0)
GlobalGT("ISNFQuest","GLOBAL",0)
Global("ISNFAreaScript1","GLOBAL",1)~THEN BEGIN Telescope000
SAY @0 /* I still remember looking at the stars, Selene hovering by my side. We could gaze at them together for hours... */
IF~~THEN REPLY @1 /* Such memories are bittersweet, aren't they? I take it from the layer of dust on this research, you aren't working on it any longer? */ GOTO Telescope001
IF~~THEN REPLY @2 /* But then she died, yes? */ GOTO Telescope002
IF~~THEN REPLY @3 /* Ugh. Such sappy stories turn my stomach. Goodbye. */ DO ~SetGlobal("ISNFObject1Talk","GLOBAL",1)~ EXIT
END

IF~~THEN BEGIN Telescope001
SAY @4 /* I have other projects to complete first. I have other priorities. */
IF~~THEN GOTO Telescope003
END

IF~~THEN BEGIN Telescope002
SAY @5 /* Yes... My research became nothing more than a troublesome burden. With her next to me the hours seemed to fly away... */
IF~~THEN GOTO Telescope003
END

IF~~THEN BEGIN Telescope003
SAY @6 /* Look, can you see this scratch here? Right here, just below the eye-piece? */
IF~~THEN REPLY @7 /* What happened to it? */ GOTO Telescope004
IF~~THEN REPLY @8 /* It's small, but I see it. */ GOTO Telescope004
IF~~THEN REPLY @9 /* I've tired of this conversation. I'll be going now. */ EXIT
END

IF~~THEN BEGIN Telescope004
SAY @10 /* Selene accidently scratched it one day while I was out. She tried her best to fix it before I got home, but she didn't know the first thing about repairing such large instruments. She knew how much I loved stargazing. */
=
@11 /* That night I came home to the most delicious wild boar pate I've ever had. Afterward, she showed me the scratch, face screwed up in fear of my displeasure. The meal was delicious, but I don't think I ever managed to explain properly that the food wasn't the reason I did not get angry with her that night. It was only because of her company that I enjoyed stargazing as much as I did in the first place. */
IF~~THEN REPLY @12 /* I wish I could have tasted it. */ GOTO Telescope005
IF~~THEN REPLY @13 /* She must have been a very kind person. */ GOTO Telescope006
END

IF~~THEN BEGIN Telescope005
SAY @14 /* The woman who made that splendid meal is long gone. */
IF~~THEN DO ~SetGlobal("ISNFObject1Talk","GLOBAL",1)~ EXIT
END

IF~~THEN BEGIN Telescope006
SAY @15 /* She was. And now she's dead. */
IF~~THEN DO ~SetGlobal("ISNFObject1Talk","GLOBAL",1)~ EXIT
END

//Books

IF~Global("ISNFObject2Talk","GLOBAL",0)
GlobalGT("ISNFQuest","GLOBAL",0)
Global("ISNFAreaScript2","GLOBAL",1)~THEN BEGIN Books000
SAY @16 /* It is hard to believe, but Selene knew every single one of those romances by heart before... before... */
IF~~THEN REPLY @17 /* Yes...? */ GOTO Books001
IF~~THEN REPLY @18 /* You don't have to say this. */ GOTO Books001
IF~~THEN REPLY @19 /* Bleh, I hate romances. */ GOTO Books002
END

IF~~THEN BEGIN Books001
SAY @20 /* Even now I stumble over the word at times. */
=
@21 /* I'm not denying the fact, even though I struggle with it. I know that sounds foolish and illogical, but it's true. */
IF~~THEN GOTO Books003
END

IF~~THEN BEGIN Books002
SAY @22 /* She loved them. */
IF~~THEN GOTO Books003
END

IF~~THEN BEGIN Books003
SAY @23 /* I think she secretly liked to pretend she was one of the heroines in her novels. It certainly explains why she was always fishing for opportunities to share tender moments with me. */
= @24 /* She always had bottles of red wine on hand, ready to be opened. If I worked too much or too long, she would open one, pour me a full glass, and plant a kiss on my cheek. She wouldn't say a word, but... */
= @25 /* That was something special. */
IF~~THEN REPLY @26 /* If all goes well, perhaps you'll have that again. */ GOTO Books004
IF~~THEN REPLY @27 /* I'm sorry. I feel for your loss. */ GOTO Books005
IF~~THEN REPLY @28 /* This is your private matter. I would rather work than talk. */ DO ~SetGlobal("ISNFObject2Talk","GLOBAL",1)~ EXIT
END

IF~~THEN BEGIN Books004
SAY @29 /* And if not...? */
IF~~THEN DO ~SetGlobal("ISNFObject2Talk","GLOBAL",1)~ EXIT
END

IF~~THEN BEGIN Books005
SAY @30 /* I don't need your shoulder to cry on as much as I need the strength and will to carry out my plans. */
IF~~THEN DO ~SetGlobal("ISNFObject2Talk","GLOBAL",1)~ EXIT
END

//Plant

IF~Global("ISNFObject3Talk","GLOBAL",0)
GlobalGT("ISNFQuest","GLOBAL",0)
Global("ISNFAreaScript3","GLOBAL",1)~THEN BEGIN Plant000
SAY @31 /* Selene always had a green thumb. I know it sounds ridiculous, but the plants practically glowed with contentment when she touched them. */
= @32 /* They will die soon now, I suppose. */
IF~~THEN DO ~SetGlobal("ISNFObject3Talk","GLOBAL",1)~ EXIT
END


//1

CHAIN IF~Global("ISNFQuest","GLOBAL",0)~THEN ISNFxOr Orion01x00
@33 /* ...My sweet Selene, why did you... */
==HaerdaJ IF~InParty("HaerDalis") !StateCheck("haerdalis",CD_STATE_NOTVALID)~ THEN @34 /* Ah, look at this mourning dove as he prays to his painting. A woman who broke his heart, perhaps. A dear friend? A lover? */
==JaheiraJ IF~InParty("Jaheira") !StateCheck("Jaheira",CD_STATE_NOTVALID)~ THEN @35 /* I do not think we are welcome here. Nor does this seem the best time to arrive uninvited. */
==KeldorJ IF~InParty("Keldorn") !StateCheck("Keldorn",CD_STATE_NOTVALID)~ THEN @36 /* I know this man. Yet I have never before seen Mister Root so depressed. */
==AnomenJ IF~InParty("Anomen") !StateCheck("Anomen",CD_STATE_NOTVALID)~ THEN @37 /* I've seen this man before. I believe he is a scientist, of sorts. */
==AerieJ  IF~InParty("Aerie") !StateCheck("Aerie",CD_STATE_NOTVALID)~ THEN @38 /* I--I'm not sure if we should be here... */
==ISNFxOr @39 /* You! Who are you? What are you doing in my estate? If you're here looking for plunder, you've wasted your time. You will find nothing of value in this place. At least, nothing that can be taken with you. */
END
IF~~THEN REPLY @40 /* Please, this is just a misunderstanding. Who are you? */ EXTERN ISNFxOr Orion01x01
IF~~THEN REPLY @41 /* You seem more than a bit depressed, wizard. Are you well? */ EXTERN ISNFxOr Orion01x02
IF~~THEN REPLY @42 /* Simply put, I'm not a thief. And you are...? */ EXTERN ISNFxOr Orion01x01


CHAIN ISNFxOr Orion01x02
@43 /* I doubt that my feelings are any real concern to you, stranger. */
==CerndJ IF ~InParty("Cernd") !StateCheck("cernd",CD_STATE_NOTVALID)~ THEN @44 /* It's been awhile since I've seen someone in such a state: dreary, and somehow lost. */
EXTERN ISNFxOr Orion01x01


CHAIN ISNFxOr Orion01x01
@45 /* Orion Root is my name. I am a scientist, an astrologer, and a man without hope. Yes, you've heard that correctly; no need to stare. If there's nothing else I can do for you, I ask that you kindly make yourselves scarce. */
==EdwinJ IF~InParty("Edwin") !StateCheck("Edwin",CD_STATE_NOTVALID)~ THEN @46 /* A scientist? Humph! I doubt he could concoct anything more complicated than a weak tea. (Such a waste of some interesting tomes and equipment.) */
==MinscJ IF~InParty("Minsc") !StateCheck("Minsc",CD_STATE_NOTVALID)~ THEN @47 /* (squeak) Yes, Boo. I think he seems a bit like Xan, too! Maybe even more than just a bit. */
END
IF~~THEN REPLY @48 /* But maybe I can do something for you? I am an adventurer. */ EXTERN ISNFxOr Orion01x03
IF~~THEN REPLY @49 /* Don't worry, I'm leaving. I wouldn't want that pool of tears leaking into my boots, anyway. */ EXTERN ISNFxOr Orion01x04
IF~~THEN REPLY @50 /* I stumbled in here looking for work, actually. I'm an adventurer and you look like someone in need. */ EXTERN ISNFxOr Orion01x03

APPEND ISNFxOr

IF~~THEN BEGIN Orion01x03
SAY @51 /* An adventurer...? I don't think that fact excuses you in any possible way. And if you consider "adventuring" getting into estates that don't belong to you, it means you don't fully understand the meaning of the word. */
= @52 /* And this offer t...! You don't even know what happened, but despite that you presume that you can help me? You think highly of yourself. */
= @53 /* Did you ever lose someone? Someone close to you. Your beloved. */
IF~~THEN REPLY @54 /* My foster father was killed, and I feel that loss deeply, but no - I've never lost a lover. */ GOTO Orion01x05
IF~~THEN REPLY @55 /* No. I don't think so. */ GOTO Orion01x05
END

IF~~THEN BEGIN Orion01x05
SAY @56 /* So you wouldn't understand. */
= @57 /* I was looking at my dead wife's portrait when you entered the estate. Do you have the ability to reverse death, *adventurer*? Don't make me laugh and stop pretending you can always help; that there's always something... */
IF~~THEN REPLY @58 /* My condolences. I didn't know. */ GOTO Orion01x06
IF~~THEN REPLY @59 /* How was I to know your wife was dead? Bah. I'm out of here. */ GOTO Orion01x04
END

IF~~THEN BEGIN Orion01x06
SAY @60 /* ... */ 
= @61 /* No...I suppose I--I shouldn't have... I apologize. */
= @62 /* My temper has been getting the better of me lately. I've been working day and night to find a way to bring her back, but.... If there even is a way - I have yet to find one. */
IF~~THEN REPLY @63 /* There must be a way. And actually there's always something - maybe you don't believe it but there is. */ GOTO Orion01x07
IF~~THEN REPLY @64 /* What about the Resurrection spell? A priest would help. */ GOTO Orion01x08
IF~~THEN REPLY @65 /* I believe you can succeed. */ GOTO Orion01x07
IF~~THEN REPLY @66 /* But that shouldn't be a problem. Just call for a priest. Any experienced one would do. */ GOTO Orion01x08
IF~~THEN REPLY @67 /* Heh, I guess I can't help you. I'll leave then. */ GOTO Orion01x04
END

IF~~THEN BEGIN Orion01x07
SAY @68 /* I've waded through every tome I possess on the subject, but I can't find an answer. I need to check one more thing... */
IF~~THEN GOTO Orion01x09
END

IF~~THEN BEGIN Orion01x08
SAY @69 /* I intended to do that, but first I wanted to be sure of a few things... */
IF~~THEN GOTO Orion01x09
END

IF~~THEN BEGIN Orion01x09
SAY @70 /* Very well. If you wish to help, I'm certainly not in a position to turn down an extra set of legs. First, I ask that you to speak to a priest in the temple of Waukeen. It is on the other side of the street, not far away from here. I'll have a reward waiting for you when you return. */
IF~Class(Player1,CLERIC_ALL) ~THEN REPLY @71 /* Actually, being a cleric myself, I am well-equipped to answer any questions you might have. */ GOTO Orion01x0C
IF~~THEN REPLY @72 /* I hope it's going to be worth the effort. */ GOTO Orion01x10
IF~~THEN REPLY @73 /* I'll do what I can. */ GOTO Orion01x10
IF~~THEN REPLY @74 /* I'm not interested. I'll leave. */ GOTO Orion01x04
END

IF~~THEN BEGIN Orion01x10
SAY @75 /* Go and ask the priest what specific conditions must be met in order to successfully raise the dead. Can something else be used to substitute the body if it was lost. */
= @76 /* While you take care of that, I shall set aside the relevant texts and read what I have on the subject. We'll compare notes when you come back. */
IF~~THEN DO ~SetGlobal("ISNFQuest","GLOBAL",1)~ EXIT
END

IF~~THEN BEGIN Orion01x0C
SAY @77 /* I mean you no offense, but I can't allow myself to trust your word just yet. The priests here at the Temple of Waukeen are known to me; someone I have met and talked to many times before. I have faith in their knowledge. */
= @78 /* I'm sorry but I'd rather you go and ask the priest there about the requirements for resurrecting the dead, and if there is any chance to substitute the body. */
= @79 /*  While you take care of that, I shall set aside the relevant texts and read what I have on the subject. We'll compare notes when you come back. */
IF~~THEN DO ~SetGlobal("ISNFQuest","GLOBAL",1)~ EXIT
END

IF~~THEN BEGIN Orion01x04
SAY @80 /* Get out of my estate then. I shall seal it this time - I need silence... */
IF~~THEN DO ~SetGlobal("ISNFQuest","GLOBAL",75)~ EXIT
END


//2

IF~OR(2) Global("ISNFQuest","GLOBAL",1) Global("ISNFQuest","GLOBAL",2) Global("ISNF3","GLOBAL",0)~THEN BEGIN Orion02x00
SAY @81 /* You are back! Did you speak with the priest? */
IF~Global("ISNFQuest","GLOBAL",2)~THEN REPLY @82 /* Yes. The body must be of good quality and not dead for too long in order for the resurrection to be successful. The only other condition is an experienced enough priest. */ GOTO Orion02x01S
IF~~THEN REPLY @83 /* No, not yet. I'll be back soon. */ EXIT
END

IF~~THEN BEGIN Orion02x01S
SAY @84 /* Hmm... */
IF~~THEN REPLY @85 /* I also asked the Sunites for help, but -- I'm sorry... */ EXTERN ISNFxOr Orion02x01
IF~~THEN REPLY @86 /* That would be all. */ EXTERN ISNFxOr Orion02x01
END
END

CHAIN IF~~THEN ISNFxOr Orion02x01
@87 /* I already knew that. My apologies for wasting your time. I thought that maybe there's some chance... some trick... Maybe I had hoped to get a different answer this time, but -- I'm afraid it doesn't work like that. */
== EdwinJ IF ~InParty("Edwin") !StateCheck("Edwin",CD_STATE_NOTVALID)~ THEN @88 /* Such a waste of my precious time. (Why do I allow this to happen?) */
== YoshJ IF ~InParty("Yoshimo") !StateCheck("Yoshimo",CD_STATE_NOTVALID)~ THEN @89 /* Some have defined madness as "repeating the same action expecting different results." If that is true, then we may be dealing with a madman. */
== YoshJ IF ~InParty("Yoshimo") !StateCheck("Yoshimo",CD_STATE_NOTVALID)~ THEN @90 /* Ah, but mind not my interjection, our skilled leader, for his work may be the opportunity to gather the gold we need. */
END
IF~~THEN REPLY @91 /* The priest advised me to ask you about the details of your wife's death. Will you tell me about her? */ EXTERN ISNFxOr Orion02x03
IF~~THEN REPLY @92 /* I know this is difficult, but I feel uncomfortable working with someone who hasn't shared his whole story with me. */ EXTERN ISNFxOr Orion02x03
IF~~THEN REPLY @93 /* You freely admit to wasting my time?! If this is a sign of what to expect from you as an employer, consider this partnership over. */ EXTERN ISNFxOr Orion02x04

CHAIN IF~~THEN ISNFxOr Orion02x03
@94 /* I suppose I should have realized you'd ask about that eventually. */
==ISNFxOr @95 /* She -- she died because of me. Selene was helping me gather research for a pet project of mine. I meant to follow up on some rumors that suggested there were priceless tomes of astrology hidden in the tombs beneath the Graveyard. She... she followed me to that very place, and... */
== NaliaJ IF ~InParty("Nalia") !StateCheck("Nalia",CD_STATE_NOTVALID)~ THEN @96 /* Don't tell me she... */
== ISNFxOr @97 /* I -- I should never have allowed her to come. There was a fire trap. I cautioned her to step over it, by placing her feet exactly where I'd placed mine. But she... she lost her balance. It was over in an instant... */
== ISNFxOr @98 /* I couldn't do anything! Do you understand that feeling? I can't sleep for remembering the smell of her burning hair, for the vision of her beautiful face melting and burning and... */
== NaliaJ IF ~InParty("Nalia") !StateCheck("Nalia",CD_STATE_NOTVALID)~ THEN @99 /* Gods... */
== AerieJ IF ~InParty("Aerie") !StateCheck("Aerie",CD_STATE_NOTVALID)~ THEN @100 /* That--that is so horrible... */
== ViconiJ IF ~InParty("Viconia") !StateCheck("Viconia",CD_STATE_NOTVALID)~ THEN @101 /* She must have been a fool to follow this worthless man. */
== MazzyJ IF ~InParty("Mazzy") !StateCheck("Mazzy",CD_STATE_NOTVALID)~ THEN @102 /* A true tragedy. No one should witness such a thing. */
== ValygarJ IF ~InParty("Valygar") !StateCheck("Valygar",CD_STATE_NOTVALID)~ THEN @103 /* That's how those who deal with magic end. If not for your curiosity and experiments, she would be alive. */
END
IF~~THEN REPLY @104 /* So it's not just because of your love for her that you wish her alive again. You blame yourself for her death. */ EXTERN ISNFxOr Orion02x05
IF~~THEN REPLY @105 /* I think I'm starting to understand you much more than before. I'm really sorry, Orion. */ EXTERN ISNFxOr Orion02x05
IF~~THEN REPLY @106 /* This job isn't what I thought. You killed your wife and you must come to terms with that on your own. */ EXTERN ISNFxOr Orion02x04

APPEND ISNFxOr

IF~~THEN BEGIN Orion02x05
SAY @107 /* I love her with my whole heart and would do anything to return her sweet smile to this world; all this - this laboratory, Athkatla...everything seems faded without her. */
= @108 /* That is how I understood that white is the Color of despair. */
IF~~THEN REPLY @109 /* I don't think I understand. */ GOTO Orion02x05N1
IF~GlobalGT("DGColoursDream","GLOBAL",10)~THEN REPLY @110 /* Colors? When you speak like that you sound like... like people from a certain distant land. Have you ever heard of the Deep Gardens? */ GOTO Orion02x05N2
IF~~THEN REPLY @111 /* White? What do you mean? */ GOTO Orion02x05N1
IF~~THEN REPLY @112 /* I'm not interested in listening to that kind of talking, Orion, so better stow it. I'm fed up with this work: you're on your own. */ GOTO Orion02x04 
IF~~THEN REPLY @113 /* That sounds right. */ GOTO Orion02x05N1
END

IF~~THEN BEGIN Orion02x05N2
SAY @114 /* What? No, I've never heard of the place. Surprising, as I thought I read about most lands of Faerun. */
= @115 /* But--what was I... ah, White. */
IF~~THEN GOTO Orion02x05N1
END

IF~~THEN BEGIN Orion02x05N1
SAY @116 /* My despair is the loss. It's like a clean canvas that can't be filled with any images. A canvas that will stay untouched forever. */
= @117 /* There were so many paintings she could create, so many moments she could fill and--I would even leave my studies behind if that could bring her back. I would sacrifice my whole past for another chance to-- */
= @118 /* But I've been talking for too long. Again, I appreciate your help. I understand if you decide you don't want to help me anymore, but if you - by any chance - want to aid me, come back. I shall prepare more gold. */
= @119 /* Thank you for listening to all of this. */
IF~~THEN DO ~SetGlobal("ISNF3","GLOBAL",1) GiveGoldForce(250) AddexperienceParty(5000)~ EXIT
END

IF~~THEN BEGIN Orion02x04
SAY @120 /* I see. Fine, here's 250 gold pieces for what you've already done. I will seal this entrance behind you so that my meditations are not disturbed again. Farewell, adventurer. */
IF~~THEN DO ~SetGlobal("ISNFQuest","GLOBAL",75) GiveGoldForce(250) AddexperienceParty(5000)~ EXIT
END

//seperated

IF~OR(2) Global("ISNFQuest","GLOBAL",1) Global("ISNFQuest","GLOBAL",2) Global("ISNF3","GLOBAL",1)~THEN BEGIN Orion02x02x00
SAY @121 /* So you are back? Does it mean you want to help me in another quest? I must warn you, this time it's going to be something more than passing a message. */
IF~~THEN REPLY @122 /* Yes. I'm not sure if what you're doing is fine, but I just can't leave you with all of this. */ GOTO Orion02x02x01
IF~~THEN REPLY @123 /* Heh, you need my help and here I come. You're a good man. You deserve some support. */ GOTO Orion02x02x01
IF~~THEN REPLY @124 /* Don't get too excited. I don't care about your loss. I just need gold. */ GOTO Orion02x02x02
IF~~THEN REPLY @125 /* No, sorry. I'm afraid it's not a good idea. Goodbye. */ GOTO Orion02x02x03
END

IF~~THEN BEGIN Orion02x02x01
SAY @126 /* I--I'm glad. Thank you. */
IF~~THEN GOTO Orion02x02x04
END

IF~~THEN BEGIN Orion02x02x02
SAY @127 /* I understand. I can't force you to feel my pain. */
IF~~THEN GOTO Orion02x02x04
END

IF~~THEN BEGIN Orion02x02x04 
SAY @128 /* As I said, the next step is much more dangerous, but you seem to be experienced enough. */
= @129 /* Down, under the flours of Athkatla, a powerful necromancer hidden somewhere under the sewers of the Temple District. He calls himself 'the Incomplete'. */
= @130 /* The results of the Incomplete's research should put me on the right path, even if it does not provide all of the answers. I need you to procure his journals and bring them here to me. If it is at all possible, then--spare his life. He's not the deadly type. He suffered, too. */
= @131 /* There's no need to spill blood when it's not necessary. All I need are his notes. */
IF~~THEN REPLY @132 /* That doesn't sound that difficult. Leave it to me. */ GOTO Orion02x02x06
IF~~THEN REPLY @133 /* Do you think he will hand over the notes and let me go? */ GOTO Orion02x02x07
IF~~THEN REPLY @134 /* I'm not about to risk my life going after some powerful necromancer. Sorry. */ GOTO Orion02x02x03
END

IF~~THEN BEGIN Orion02x02x06
SAY @135 /* Be careful. The Incomplete is powerful and should not be underestimated. But maybe you will manage to persuade him. Maybe he will understand that there is no need to run away. But--but if you must, end his dark existence. */
IF~~THEN GOTO Orion02x02x08
END

IF~~THEN BEGIN Orion02x02x07
SAY @136 /* Maybe. But the chance is really small. */
IF~~THEN GOTO Orion02x02x08
END

IF~~THEN BEGIN Orion02x02x08
SAY @137 /* I know that the mission may sound easy, but please, remember that it's not an ordinary necromancer you're going to face. The Incomplete is... it's really hard to explain. But his experiments changed him. */
= @138 /* But again - remember that he was a normal human once. It may be strange that I ask you to have mercy for the one I tell you to find, but at least try. */
= @139 /* We've seen so much blood already. */
IF~~THEN DO ~SetGlobal("ISNFQuest","GLOBAL",3)~ EXIT
END

IF~~THEN BEGIN Orion02x02x03
SAY @140 /* Come back if you change your mind. Please. */
IF~~THEN EXIT
END

//3

IF~OR(2) Global("ISNFQuest","GLOBAL",3) Global("ISNFQuest","GLOBAL",4)~THEN BEGIN Orion03x00
SAY @141 /* Were you successful? Did you find the Incomplete? */
IF~Global("ISNFQuest","GLOBAL",4)~THEN REPLY @142 /* I did. */ EXTERN ISNFxOr Orion03x01
IF~~THEN REPLY @143 /* No, not yet. sorry. */ EXIT
END
END

CHAIN IF~~THEN ISNFxOr Orion03x01
@144 /* Excellent. Hand over the journal, if you please. */
==CerndJ IF ~InParty("Cernd") !StateCheck("Cernd",CD_STATE_NOTVALID)~ THEN @145 /* He didn't even ask about 'the Incomplete'. How blind is he? */
END
IF~PartyHasItem("ISNFxJ")~THEN REPLY @146 /* Yes, but before I give it up, I'd like to know if you truly betrayed your friend in the manner he spoke of. */ EXTERN ISNFxOr Orion03x03
IF~~THEN REPLY @147 /* I have it, but I won't be turning it over to you. He was your friend, and you just let him become a monster? You are despicable and don't deserve to live. */ EXTERN ISNFxOr Orion03x04
IF~~THEN REPLY @148 /* No, I lost it somewhere. Give me a moment. I've got to find it. */ EXTERN ISNFxOr Orion03x05
IF~~THEN REPLY @149 /* No and you won't get it. I had to kill the Incomplete, but he told me how you abandoned him to such a horrific fate. I've returned to end you, Orion. */ EXTERN ISNFxOr Orion03x04

APPEND ISNFxOr

IF~~THEN BEGIN Orion03x03
SAY @150 /* I won't stand here and say none of it was my fault, but he knew the dangers when he came to my aid. */
=
@151 /* He was a good friend - one of the best I ever had - and when Selene died, he was eager and willing to help me get her back. He volunteered to subject himself to every risky experiment we dreamt up, and in my desperation, I let him. He was always a bit too ambitious for his own good... When the results of our research were different from what we expected them to be, we managed to attract the attention of Cowled Wizards. */
=
@152 /* By this point, he'd already begun to transform. His--our experiments had left him fundamentally altered to the point that any passing Cowled Wizard could have detected it. For his safety, and to preserve our research, we decided that he had to go into hiding while I covered our tracks. */
=
@153 /* He made his hideout in the sewers, but with time became bitter over the arrangement. It didn't help that his 'Incomplete' persona was changing him more and more each day. At first, we communicated by letters. I told him how I was researching a way to reverse his condition in addition to my work on Selene's rebirth. As time went by, he grew impatient and accused me of leaving him to rot in that state. I lost contact with him when he stopped returning my messages. */
IF~~THEN REPLY @154 /* This all sounds very reasonable, but on the other hand, you yourself call him 'the Incomplete'. You could at least use his name. He was a man once, and more than that, your friend. */ GOTO Orion03x06
IF~~THEN REPLY @155 /* I understand. It was difficult, but you had to sacrifice him for your wife's recovery. I suppose in your position I would have done the same. */ GOTO Orion03x07
IF~~THEN REPLY @156 /* You let him live in the sewers. You abandoned him. You should at least call him by his name, Orion. */ GOTO Orion03x06
IF~~THEN REPLY @157 /* This isn't right. You're insinuating he was just a tool in your plan. I won't help you in your wicked game. */ GOTO Orion03x04
END

IF~~THEN BEGIN Orion03x06
SAY @158 /* His name was Xerxes and he was indeed my friend. */
= @159 /* ...and I presume you killed him... I'll miss him, but at least he doesn't have to hide any more. */
IF~~THEN GOTO Orion03x08
END

IF~~THEN BEGIN Orion03x07
SAY @160 /* I'm glad that you understand. If you killed him, that means he doesn't have to hide any more. I hope that he didn't suffer much. */
IF~~THEN GOTO Orion03x08
END

IF~~THEN BEGIN Orion03x08
SAY @161 /* In the end, his death won't have been in vain. Here's your reward for the task. I'll need some time for myself now to wade through all of his notes. */
=
@162 /* Come back in two days if you find you are still able to work with me. I'm not going to abandon my goal and I may need some more help. */
IF~~THEN DO ~SetGlobal("ISNFQuest","GLOBAL",5) GiveGoldForce(1000) AddexperienceParty(8000) TakePartyItem("ISNFxJ") DestroyItem("ISNFxJ") SetGlobalTimer("ISNFTime1","GLOBAL",TWO_DAYS)~ EXIT
END

IF~~THEN BEGIN Orion03x04
SAY @163 /* I'm sorry that you see it that way, but I won't abandon my mission. I can't. */
IF~~THEN DO ~SetGlobal("ISNFQuest","GLOBAL",75)~ EXIT
END

IF~~THEN BEGIN Orion03x05
SAY @164 /* Damn. Well I suppose I still have a few more tomes to go over. Hurry, will you? */
IF~~THEN EXIT
END


//4

IF~Global("ISNFQuest","GLOBAL",5) !GlobalTimerExpired("ISNFTime1","GLOBAL")~THEN BEGIN Orion04x00
SAY @165 /* Damn! You interrupted me and now I've lost my place. This will set me back at least an hour... */
IF~~THEN EXIT
END

//5

IF~Global("ISNFQuest","GLOBAL",5) GlobalTimerExpired("ISNFTime1","GLOBAL")~THEN BEGIN Orion05x00
SAY @166 /* Ah, I hoped you would return. I wish I could say I have found a better solution, but...this one... */
= @167 /* (Sits down) I feel useless! I wasted nearly fifty hours on his notes, and yet I am unable to find a REAL solution. How pathetic. Gods, Selene, how did you ever love me?! I've studied so much, I should have found more than that. */
IF~~THEN REPLY @168 /* Are you serious? You've come this far and you plan to just give up?! */ GOTO Orion05x001
IF~~THEN REPLY @169 /* Pull yourself together. Who is going to resurrect your beloved if you do not? */ GOTO Orion05x001
IF~~THEN REPLY @170 /* I will help you make your decision. This thing... it kills you. I won't be a part of something so unnatural. */ GOTO Orion05x03
IF~~THEN REPLY @171 /* I'm fed up with you. Do what you want, but on your own. */ GOTO Orion05x03
END

IF~~THEN BEGIN Orion05x001
SAY @172 /* (Stands up, but almost loses balance) No... you're right. I... I shouldn't give up... */
IF~~THEN REPLY @173 /* Are you alright? */ GOTO Orion05x002
IF~~THEN REPLY @174 /* Just tell me what to do. */ GOTO Orion05x003
IF~~THEN REPLY @175 /* Woah, sit down for another moment! Look at you - you're exhausted. Did you sleep at all these past seven days? */ GOTO Orion05x002
END

IF~~THEN BEGIN Orion05x002
SAY @176 /* Heh...it's alright. I can still work. Thank you for your concern, though. I had no sleep for last two days; I didn't want to waste any time and... */
= @177 /* I hope you are prepared for your next task. It's easy but... I will read through the notes for the last time. I just have to. */
IF~~THEN GOTO Orion05x003
END

IF~~THEN BEGIN Orion05x003
SAY @178 /* Meanwhile, I need you to find an artist who can sculpt clay and commission a sculpture of Selene using this portrait of her. We'll need it later. */
= @179 /* I know this sounds strange, but it truly is important. It will become a kind of link and...oh, I just find it difficult to tell you all the details right now. (Becomes even paler and sits down again) */
IF~~THEN REPLY @180 /* Very well. I'll be back. But you should rest while I'll be looking for the artist. I'll check the Sune's temple. They're always into art. */ GOTO Orion05x01
IF~~THEN REPLY @181 /* Maybe I wouldn't feel so strange about it if you told me what it will be used for. */ GOTO Orion05x02
IF~~THEN REPLY @182 /* I've survived this long by trusting my gut instincts. Right now they're telling me to bow out of this while I can. */ GOTO Orion05x03
END

IF~~THEN BEGIN Orion05x01
SAY @183 /* Good idea. I...I may try to rest, but I have to check one more thing... */
IF~~THEN DO ~SetGlobal("ISNFQuest","GLOBAL",6)~ EXIT
END

IF~~THEN BEGIN Orion05x02
SAY @184 /* If I ever want to see her face again, I need someone to recreate her form - that will be the link. There is no point in describing the process any further than that before this next step is complete. Now please, let me check the notes for the last time... */
IF~~THEN DO ~SetGlobal("ISNFQuest","GLOBAL",6)~ EXIT
END

IF~~THEN BEGIN Orion05x03
SAY @185 /* Fine. I will just have to continue on my own once I've had a rest. I shall seal the door - I need some silence. Farewell. */
IF~~THEN DO ~SetGlobal("ISNFQuest","GLOBAL",75)~ EXIT
END

//6

IF~Global("ISNFQuest","GLOBAL",7)~THEN BEGIN Orion06x00
SAY @186 /* I spoke to the artist. Thank you. I have a reward for you here in the amount of 1200 gold pieces. The sculptor told me that the work won't be ready for a while. I plan to use that time to rest up and make preparations. You should return at the end of three days. I won't have any more work for you to do until then. */
= @187 /* Gods, I can't believe we're almost there; that...that I may be able to see her again. */
= @188 /* Again - thank you... */
IF~~THEN REPLY @189 /* You deserve to see her. */ GOTO Orion06x01
IF~~THEN REPLY @190 /* Mhm. It's good you appreciate my help. */ GOTO Orion06x01
END

IF~~THEN BEGIN Orion06x01
SAY @191 /* (looks at Selene's portrait) It's been so long... */
IF~~THEN REPLY @192 /* Prepare everything you may need. I shall be back in three days. */ GOTO Orion06x02
IF~~THEN REPLY @193 /* Look, we have three days. We should go somewhere -- to a tavern, probably. You should take a breath, you know. */ GOTO Orion06x03
END

IF~~THEN BEGIN Orion06x03
SAY @194 /* I'm not sure... */
IF~CheckStatGT(Player1,12,CHR)~THEN GOTO Orion06x04
IF~CheckStatLT(Player1,13,CHR)~THEN GOTO Orion06x05
END

IF~~THEN BEGIN Orion06x02
SAY @195 /* We shall meet here. */
IF~~THEN DO ~SetGlobal("ISNFQuest","GLOBAL",8) GiveGoldForce(1200) AddexperienceParty(5000) SetGlobalTimer("ISNFTime2","GLOBAL",THREE_DAYS)~ EXIT
END

IF~~THEN BEGIN Orion06x04
SAY @196 /* ...maybe you're right. I would like to tell you how we met for the first time. I need to remember that time to succeed, and you are a good friend - I think I can tell you... */
= @197 /* If you want to talk to me before more things happen, meet me at the Delosar's Inn in the Bridge District before three days pass. Later we won't have time for talking. I will have to proceed without sharing my memories with you. */
IF~Global("ISNFWeCanMeet","GLOBAL",0)~THEN DO ~SetGlobal("ISNFQuest","GLOBAL",8) SetGlobal("ISNFWeCanMeet","GLOBAL",1) GiveGoldForce(1200) AddexperienceParty(5000) SetGlobalTimer("ISNFTime2","GLOBAL",THREE_DAYS)~ EXIT
END

IF~~THEN BEGIN Orion06x05
SAY @198 /* I'm sorry, but I think I just should stay here... I don't think talking can do me any good. I just need to prepare. */
IF~~THEN DO ~SetGlobal("ISNFQuest","GLOBAL",8) GiveGoldForce(1200) AddexperienceParty(5000) SetGlobalTimer("ISNFTime2","GLOBAL",THREE_DAYS)~ EXIT
END

//7miss

IF~Global("ISNFQuest","GLOBAL",8) !GlobalTimerExpired("ISNFTime2","GLOBAL")~THEN BEGIN Orion07x0x
SAY @199 /* We can't continue without the sculpture. Visit me again later. */
IF~~THEN EXIT
END

//7 

IF~Global("ISNFQuest","GLOBAL",8) GlobalTimerExpired("ISNFTime2","GLOBAL")~THEN BEGIN Orion07x00
SAY @200 /* My Selene... it feels like an eternity has passed since I last looked upon your beautiful smiling face... */
= @201 /* I miss you, my dearest heart. I swear, I WILL hold you again. */
IF~~THEN REPLY @202 /* (cough) */ GOTO Orion07x01
IF~~THEN REPLY @203 /* I don't mean to intrude, but you did say to return in three days, correct? */ GOTO Orion07x01
END

IF~~THEN BEGIN Orion07x01
SAY @204 /* Ah, it is you. As you can see, the sculpture is ready. Now...now we need to focus on the most difficult element of this puzzle. We need to bring back Selene's soul. */
IF~~THEN REPLY @205 /* You mean HER soul? How...how is that even possible? */ GOTO Orion07x02
IF~~THEN REPLY @206 /* Very interesting. Tell me the details. */ GOTO Orion07x02
IF~~THEN REPLY @207 /* I'm not going to help! You're insane! */ GOTO Orion07x03
END

IF~~THEN BEGIN Orion07x02
SAY @208 /* She's in the Underground. The dead do not actually disappear, you see. They can be met in a kind of... void. She just needs a body - and here it is. Her original body is burned of course, but this sculpture shall become the new 'flask' for her energy. */
= @209 /* I know how it sounds, but... you should know that I tried everything else, that...that I would rather use any different method that this one. But there's no chance for a different way. */
= @210 /* While I can prepare the ritual, I can't go to the Underground myself. I need someone to go in on my behalf and bring her out to me. */
= @211 /* I want you to find her. Please. */
IF~~THEN REPLY @212 /* Isn't this dangerous? */ GOTO Orion07x04
IF~~THEN REPLY @213 /* This is sick. I won't help you! */ GOTO Orion07x03
END

IF~~THEN BEGIN Orion07x04
SAY @214 /* It may be, Child of Bhaal. */
IF~~THEN REPLY @215 /* How can you know about my heritage?! */ GOTO Orion07x05
IF~~THEN REPLY @216 /* So you know about me. I have no idea why I thought you just trusted me, I should have known you only needed my heritage. */ GOTO Orion07x05
IF~~THEN REPLY @217 /* Are you finally showing your true colors then, wizard?. */ GOTO Orion07x05
END

IF~~THEN BEGIN Orion07x05
SAY @218 /* I had to check up on you. I asked some... former colleagues to find information about you. With a bloodline like yours, you can enter the void and get the soul of my wife back. */
= @219 /* Please, there's no other way! And please, know that your heritage isn't the reason I talked to you about my pain. I told you all this because I trust you and--you appeared to be a friend. */
= @220 /* You will be able to stop the vengeful souls. You're the Bhaalspawn. I'll pay you 10000 gold pieces, if you need money. That's all that I have left in the world... and I'll give it up to you joyfully if you just bring my Selene back to me. */
= @221 /* Please... I trust you. */
IF~~THEN REPLY @222 /* Very well. Let's get this over with. */ GOTO Orion07x06
IF~~THEN REPLY @223 /* No! I'm not going to do this and neither should you! You should forget about your wife. She's dead. */ GOTO Orion07x03
END

IF~~THEN BEGIN Orion07x06
SAY @224 /* May the gods bless your generous heart! Now, all we need is the right word. */
=@225 /* (He walks toward you and touches your forehead. You feel him mark a wet trail across your skin there, and when he withdraws his hand, you see that his fingers are stained red with blood. He says a word you can't hear and everything disappears.) */
IF~~THEN DO ~SetGlobal("ISNFQuest","GLOBAL",9) FadeToColor([20.0],0) ActionOverride(Player1,LeaveAreaLUA("ISNF04","",[450.380],4)) FadeFromColor([20.0],0) CreateVisualEffectObject("SPPORTAL",Player1)~ EXIT
END

IF~~THEN BEGIN Orion07x03
SAY @226 /* I'm sorry, but I've come too far to stop now. You are free to go, but I will seal this place shut behind you. I WILL find a way to reach her on my own. */
IF~~THEN DO ~SetGlobal("ISNFQuest","GLOBAL",75)~ EXIT
END


//8

IF~Global("ISNFQuest","GLOBAL",10)~THEN BEGIN Orion08x00
SAY @227 /* You're back? Where is she then? Is her soul in the sculpture? Yes, it--it must be inside... */
IF~~THEN REPLY @228 /* I'm sorry, Orion, but she can't be brought back to life. */ EXTERN ISNFxOr Orion08x01
IF~~THEN REPLY @229 /* I found her, but she told me that she can't come back. */ EXTERN ISNFxOr Orion08x01
IF~~THEN REPLY @230 /* I... erm... think something went wrong. The ritual, I mean. I just fainted. */ EXTERN ISNFxOr Orion08x01
END
END

CHAIN IF~~THEN ISNFxOr Orion08x01
@231 /* You didn't bring her back?! If this... if this couldn't work, nothing will! */
== AnomenJ IF ~InParty("Anomen") !StateCheck("Anomen",CD_STATE_NOTVALID)~ THEN @232 /* Calm down, mage! She's dead. We can't bring her back. */
==ISNFxOr @60 /* ... */
==ISNFxOr@233 /* I'm sorry, but to get your reward, you must first kill me. I will join her. If death is the only way to be with her, so be it! */
== KeldorJ IF ~InParty("Keldorn") !Dead("Keldorn") !StateCheck("Keldorn",STATE_DEAD)~ THEN @234 /* You should not do this, Orion. Do you really believe that's what Selene would have wanted? */
== ISNFxOr IF ~InParty("Keldorn") !Dead("Keldorn") !StateCheck("Keldorn",STATE_DEAD)~ THEN @235 /* You can't understand, Sir Firecam. You might be able to leave your loved ones behind, but not I. */
== ISNFxOr IF ~InParty("Keldorn") !Dead("Keldorn") !StateCheck("Keldorn",STATE_DEAD)~ THEN @236 /* I've seen you leaving them – your wife, your children – alone, in that empty house. For days – weeks, even! I could never understand you; no duty could be that important. */
== Imoen2J IF ~InParty("Imoen2") !Dead("Imoen2") !StateCheck("Imoen2",STATE_DEAD)~ THEN @237 /* Please, we've seen  enough pain, Orion. Don't make this worse. */
== KorganJ IF ~InParty("Korgan") !Dead("Korgan") !StateCheck("Korgan",STATE_DEAD)~ THEN @238 /* Ha! That's what I'm talking about! Finally, we'll have some fightin'! */
== NaliaJ IF ~InParty("Nalia") !Dead("Nalia") !StateCheck("Nalia",STATE_DEAD)~ THEN @239 /* Mister Orion, please! There are many that could use your help! And aiding others may ease your pain. At least some of it. */
== AerieJ IF ~InParty("Aerie") !Dead("Aerie") !StateCheck("Aerie",STATE_DEAD)~ THEN @240 /* P-please! We...we can't just let it end this way... */
== ValygarJ IF ~InParty("Valygar") !Dead("Valygar") !StateCheck("Valygar",STATE_DEAD)~ THEN @241 /* You've made many mistakes, wizard. Too many. Calm down, or I won't hesitate to end your life. */
== MazzyJ IF ~InParty("Mazzy") !Dead("Mazzy") !StateCheck("Mazzy",STATE_DEAD)~ THEN @242 /* By Avoreen, we've no reason to fight you! It doesn't make any sense. */
== ViconiJ IF ~InParty("Viconia") !Dead("Viconia") !StateCheck("Viconia",STATE_DEAD)~ THEN @243 /* You must be a fool to even think of attacking us. You will have your death, rivvil, but you will suffer, first. Shar, mark my words! */
END
IF~~THEN REPLY @244 /* It doesn't have to end like that, Orion. */ EXTERN ISNFxOr Orion08x02
IF~~THEN REPLY @245 /* Orion, please! That's madness! */ EXTERN ISNFxOr Orion08x02
IF~~THEN REPLY @246 /* If this is what you want, I won't refuse. Prepare yourself! */ EXTERN ISNFxOr Orion08x03

APPEND ISNFxOr

IF~~THEN BEGIN Orion08x02
SAY @247 /* This is the only way! What is life without her warm breath, the scent of her hair, the touch of her cheek...?! I have been dead since the moment her soul departed this world. My body carried on only to try and return her to the light. */
= @248 /* I trusted you! I trusted you as...as if you were my own brother! But even though you betrayed me! */
IF~~THEN REPLY @249 /* Orion, please... */ GOTO Orion08x03
IF~~THEN REPLY @250 /* No. It's not like that, Orion. You need to calm down. */ GOTO Orion08x03
IF~~THEN REPLY @251 /* Fine, I did. So? What are you going to do? Kill me? Ha! */ GOTO Orion08x03
END

IF~~THEN BEGIN Orion08x03
SAY @252 /* I was right in the very beginning. I shouldn't have trusted you. You've seen her; you've been to the Other Side; you've seen the Colours of those who faded away... she was there, but you - *you* let her stay. */
IF~~THEN REPLY @253 /* She told me that there's no way back. Why can't you just believe me? */ GOTO Orion08x04
IF~~THEN REPLY @254 /* Life is not a toy, Orion. You can't just fix it once it's broken. */ GOTO Orion08x04
END

IF~~THEN BEGIN Orion08x04
SAY @255 /* I-- */
= @256 /* (He becomes pale for a moment; something has changed, as if an invisible and desperate power grasped him; now, his breath is less rhythmical; shallow.) */
= @257 /* I thought you would help...and I can stand no more of this--of all of this. */
IF~~THEN REPLY @258 /* That's why you have to forget. */ GOTO Orion08x05
IF~~THEN REPLY @259 /* There are many women. I am sure you will fall in love again, Orion. */ GOTO Orion08x05
IF~~THEN REPLY @260 /* Eh, this is pathetic. */ GOTO Orion08x05
END

IF~~THEN BEGIN Orion08x05
SAY @261 /* What?! */
= @262 /* You shall pay for everything! You are the new one to blame! I lost her again - because of you! You will suffer. Now, it's you or me. I will have my revenge or--or I will join her. */
= @263 /* ...I refuse to spend another moment on this wretched soil without her... */
= @264 /* Do me this last kindness and send me into her arms as swiftly as you can...or die yourself... */
IF~~THEN DO ~SetGlobal("ISNFQuest","GLOBAL",11)~ EXIT
END
END