BEGIN ISNFxEn

CHAIN IF~Global("ISNFQuest","GLOBAL",3)~THEN ISNFxEn ISNFxEnemy100
@0 /* I can see you, vile creature! I see the blood on your hands! Even your steps stink of death. Why are you here? I don't want to see anyone. I want to stay alone. Just...alone. */
== AnomenJ IF ~InParty("Anomen") !StateCheck("Anomen",CD_STATE_NOTVALID)~ THEN @1 /* How dare you question us, monster? You're the one who should not be here! */
== CerndJ IF ~InParty("Cernd") !StateCheck("Cernd",CD_STATE_NOTVALID)~ THEN @2 /* What unnatural being is that? Pale as birch, and disturbing as a storm. */
== EdwinJ IF ~InParty("Edwin") !StateCheck("Edwin",CD_STATE_NOTVALID)~ THEN @3 /* Hmm. It must be a powerful undead, of some sort. (It would make an interesting subject of study.) */
== AerieJ IF ~InParty("Aerie") !StateCheck("Aerie",CD_STATE_NOTVALID)~ THEN @4 /* I--I don't like this thing! Whatever you are, keep away! */
== MazzyJ IF ~InParty("Mazzy") !StateCheck("Mazzy",CD_STATE_NOTVALID)~ THEN @5 /* What manner of creature is this? */
END 
IF~~THEN REPLY @6 /* I come only for your research. Orion sent me. */ GOTO ISNFxEnemy101
IF~~THEN REPLY @7 /* My employer sent me here to fetch your journal. */ GOTO ISNFxEnemy102
IF~~THEN REPLY @8 /* Your death brings me here. Die, beast! */ GOTO ISNFxEnemy103

APPEND ISNFxEn

IF~~THEN BEGIN ISNFxEnemy101
SAY @9 /* I suppose I should have guessed that. */
IF~~THEN GOTO ISNFxEnemy104
END

IF~~THEN BEGIN ISNFxEnemy102
SAY @10 /* Employer? You must mean Orion. */
IF~~THEN GOTO ISNFxEnemy104
END

IF~~THEN BEGIN ISNFxEnemy103
SAY @11 /* No, not yet. I can smell Orion on you. He is the one who sent you, is he not? */
IF~~THEN GOTO ISNFxEnemy104
END

IF~~THEN BEGIN ISNFxEnemy104
SAY @12 /* Why do you bother the Incomplete? Is it again because of my work? No matter how deep I do, he would still send some adventurers only to get it. Why can't he leave me be? There is a type of knowledge people shouldn't have. You should go and tell him that. */
IF~~THEN REPLY @13 /* You sound quite sane. I expected something that hides underground to be more monstrous. */ GOTO ISNFxEnemy10N1
IF~~THEN REPLY @14 /* I'm afraid that he really wouldn't be satisfied with these words, monster. But still, you surprise me. I thought someone of your kind would attack on sight. */ GOTO ISNFxEnemy10N2
IF~~THEN REPLY @15 /* I'm fed up with this discussion. Just die, monster. */ GOTO ISNFxEnemy107
IF~~THEN REPLY @16 /* I am surprised. I was sent to find a changeling; an unnatural creature, but I've found a poor man down here. I can tell you're not evil. */ GOTO ISNFxEnemy10N3
END

IF~~THEN BEGIN ISNFxEnemy10N1
SAY @17 /* Something more monstrous? So now I am considered just an imitation of a human being? I'm not even a "someone"? Maybe you're right. Maybe I no longer deserve to be called human. */
IF~~THEN GOTO ISNFxEnemy10N6
END

IF~~THEN BEGIN ISNFxEnemy10N2
SAY @18 /* Monster? I-- */
= @19 /* No, you're right. I am a monster. I no longer deserve to be called a human being. */
IF~~THEN GOTO ISNFxEnemy10N6
END

IF~~THEN BEGIN ISNFxEnemy10N3
SAY @20 /* What...? I tried to hide; I live in a damned place under the Sewers and yet you call me a poor man? Even with a face like this? Just look at it. */
IF~~THEN REPLY @21 /* It's white. One man said that white is the shade of loss and despair. And indeed you have lost something. I'm sorry. */ GOTO ISNFxEnemy10N5
IF~~THEN REPLY @22 /* It seems that even a poor man can become a monster. You're right - you are no longer a human being. */ GOTO ISNFxEnemy10N2
END

IF~~THEN BEGIN ISNFxEnemy10N5
SAY @23 /* ... */
= @24 /* It was just some time ago, but... it's in the past. Stop reminding me about what has happened. When you say these words, they just echo with more pain. */
IF~~THEN GOTO ISNFxEnemy10N6
END

IF~~THEN BEGIN ISNFxEnemy10N6
SAY @25 /* It seems that you came to my home without knowing my past. Are you curious why I'm called by this name? Did Orion tell you? */
IF~~THEN REPLY @26 /* Did he tell me what? */ GOTO ISNFxEnemy105
IF~~THEN REPLY @27 /* Hmm, and again someone didn't tell me everything. Eh, why does it happen all the time... */ GOTO ISNFxEnemy106
IF~~THEN REPLY @28 /* (Lie) Yes. Can I kill you now? */ GOTO ISNFxEnemy107
END

IF~~THEN BEGIN ISNFxEnemy105
SAY @29 /* I thought so. He didn't. */
IF~~THEN GOTO ISNFxEnemy108
END

IF~~THEN BEGIN ISNFxEnemy106
SAY @30 /* It seems he was ashamed after all. */
IF~~THEN GOTO ISNFxEnemy108
END

IF~~THEN BEGIN ISNFxEnemy107
SAY @31 /* No and such annoying lies are useless against me. I can see through your bluff, fool. */
IF~~THEN GOTO ISNFxEnemy108
END

IF~~THEN BEGIN ISNFxEnemy108
SAY @32 /* Look at me - this face changed, but it didn't happen years ago. It was a matter of weeks. Do you wonder, perhaps, how was it that he became a monster without a purpose in life; hiding amidst the scum of the sewers? */
= @33 /* I am the Incomplete, the one who studied Necromancy. I studied it to help a friend. But in the end it was me who changed into this hollow form. */
= @34 /* I risked everything in my research, because he knew I was skilful enough to reach beyond the boundaries of ordinary magic. The result of all that work left me as I am now. */
= @35 /* I have lost everything that once made me a man. I am trapped between life and death because of HIS loss. I wanted to bring his precious Selene back and in the end, once he had everything he could glean from my work, he simply... he advised me to hide. As if I were nothing more than a dog at his feet. */
= @36 /* He didn't want to kill me, no. But he knew I couldn't stay among normal people. They wouldn't listen. They would consider me a monster, nothing more. */
= @37 /* I was furious so I took the results of my study with me. */
IF~~THEN REPLY @38 /* Why didn't you kill him? */ GOTO ISNFxEnemy109
IF~~THEN REPLY @39 /* And you just left? Without a final word? Without a fight? */ GOTO ISNFxEnemy109
IF~~THEN REPLY @40 /* If he knew the results of your studies, then why would he require your journal now? */ GOTO ISNFxEnemy110
END

IF~~THEN BEGIN ISNFxEnemy109
SAY @41 /* I considered it briefly, and decided not to, for some reason. I cannot fathom what my reasoning was at that time, but that's not surprising. I can barely remember anything about my former life these days. I can remember nothing but my last three months. */
IF~~THEN GOTO ISNFxEnemy111
END

IF~~THEN BEGIN ISNFxEnemy110
SAY @42 /* I presume he has run out of options and is desperate to find something he may have missed. */
IF~~THEN GOTO ISNFxEnemy111
END

IF~~THEN BEGIN ISNFxEnemy111
SAY @43 /* I won't be handing my journals over to anyone in his employ. He was a brother to me in many ways, once, yet he let me lose my humanity. My soul was the price he paid to gain the knowledge he wanted, and it should never have been his to barter with. */
= @44 /* I'm not a man; I'm not a lich. I am the Incomplete. How much farther will he go to see his dead wife again? Tell me! */
IF~~THEN REPLY @45 /* What happened to you is unfortunate, but Orion has suffered much as well! His ends are good, even if his means were not. */ GOTO ISNFxEnemy112
IF~~THEN REPLY @46 /* You say this only because you are no longer human. Is there nothing in your heart that remembers loyalty and devotion to another? */ GOTO ISNFxEnemy113
IF~~THEN REPLY @47 /* So what should I do then? */ GOTO ISNFxEnemy114
END

IF~~THEN BEGIN ISNFxEnemy112
SAY @48 /* I suppose I cannot change your mind. Maybe that's good. Maybe with someone like you at his side he won't become like me. Or at least he won't stay alone in all of this madness. */
IF~~THEN GOTO ISNFxEnemy115
END

IF~~THEN BEGIN ISNFxEnemy113
SAY @49 /* I... */
=
@50 /* I don't know what I should tell you. */
IF~~THEN GOTO ISNFxEnemy115
END

IF~~THEN BEGIN ISNFxEnemy114
SAY @51 /* I'm not going to tell you. I'm not going to take part in all this. I am fed up. */
IF~~THEN GOTO ISNFxEnemy115
END

IF~~THEN BEGIN ISNFxEnemy115
SAY @52 /* Now I can feel the void growing inside my chest. Inside my hands and legs and eyes. You can't understand it. You have no idea how it feels to be the Incomplete; how it feels to miss some parts inside. */
= @53 /* It's like... like being broken. */
= @54 /* My journals are yours to do with as you will, if you can defeat me. My soul has yearned for the completion of death ever since the moment I awoke to this accursed state. */
= @55 /* No matter what your ultimate decision is, remember that actions have consequences. And now complete my destiny. Let this end. */
IF~~THEN DO ~SetGlobal("ISNFQuest","GLOBAL",4) PlaySound("ISNF03") Enemy()~ EXIT
END
END
