BEGIN ISNFxGO

IF~Global("ISNFGorionMemory","GLOBAL",0)~THEN BEGIN ISNFGorion000
SAY @0 /* Who--who's here? I told you, my child, I need to study these books. I'm sure that you can find something for yourself, too. Over there probably. */
IF~~THEN REPLY @1 /* This...this is impossible. You can't be Gorion. */ GOTO ISNFGorion001
IF~~THEN REPLY @2 /* That must be the result of my own presence. Even though I didn't open the door. */ GOTO ISNFGorion002
IF~~THEN REPLY @3 /* Gorion...? */ GOTO ISNFGorion003
END

IF~~THEN BEGIN ISNFGorion001
SAY @4 /* What's wrong, my child? Ah, you must have been playing games with Imoen and hit your head again. You should be more thoughtful, otherwise you'll get three dozen bruises before you even start an adventure of your own. */
IF~~THEN GOTO ISNFGorion004
END

IF~~THEN BEGIN ISNFGorion002
SAY @5 /* The door? If you're here, then you must have opened the door. Ah, you must have been playing games with Imoen and hit your head again. You should be more thoughtful, otherwise you'll get three dozen bruises before you even start an adventure of your own. */
IF~~THEN GOTO ISNFGorion004
END

IF~~THEN BEGIN ISNFGorion003
SAY @6 /* Should I say "yes" to make my child recognise me? Ah, you must have been playing games with Imoen and hit your head again. You should be more thoughtful, otherwise you'll get three dozen bruises before you even start an adventure of your own. */
IF~~THEN GOTO ISNFGorion004
END

IF~~THEN BEGIN ISNFGorion004
SAY @7 /* I believe you should rest for a while, study, read books, probably, to make sure you know some facts before you become an adult of your own, <CHARNAME>. */
IF~~THEN REPLY @8 /* *Why? Nothing ever happens in Candlekeep anyway, and I doubt you will EVER let me leave these walls.* */ GOTO ISNFGorion005
IF~~THEN REPLY @9 /* Smart as always. I missed you, Gorion. */ GOTO ISNFGorion006
IF~~THEN REPLY @10 /* You're just a memory. I don't need you! Begone, I care not for the past! */ GOTO ISNFGorion007
END

IF~~THEN BEGIN ISNFGorion005
SAY @11 /* Hoho, how can you be that sure? But the truth is that you're not ready. You should learn more before you go anywhere. You don't want people to pity you, do you? */
IF~~THEN GOTO ISNFGorion008
END

IF~~THEN BEGIN ISNFGorion006
SAY @12 /* Missed me? We've seen each other in the morning. You must have hurt your head really badly. You should rest for a while. Maybe ask Winthrop to prepare you some chicken soup. Then you should be back and study some more. */
IF~~THEN GOTO ISNFGorion008
END

IF~~THEN BEGIN ISNFGorion008
SAY @13 /* You may think that it's the rumbling of an old man, but trust me - one day you will need all of this knowledge. There are plenty who would like to wade through the books of our Library, but only few may actually see the inner walls of our keep. */
IF~~THEN REPLY @14 /* You overestimate this knowledge, Gorion. Books would never prepare me for... anything that may happen. */ GOTO ISNFGorion009
IF~~THEN REPLY @15 /* *Sometimes I would rather be one of those on the outside of Candlekeep than...kept in all of these walls. There must be so many places...* */ GOTO ISNFGorion010
IF~~THEN REPLY @16 /* Begone, memory. You're not Gorion; I'm not here to talk to you. */ GOTO ISNFGorion007
END

IF~~THEN BEGIN ISNFGorion009
SAY @17 /* You sound different today. */
= @18 /* I know you may feel that all this is nothing, but--trust me and trust this place. Even though it may not seem that way all the time, you have friends here. Many will remember your name. */
IF~~THEN GOTO ISNFGorion011
END

IF~~THEN BEGIN ISNFGorion010
SAY @19 /* --You will see them. Patience, my child. Soon, you will be ready. */
IF~~THEN GOTO ISNFGorion011
END

IF~~THEN BEGIN ISNFGorion011
SAY @20 /* I suppose I won't succeed in making you learn today. You can go. Just don't get into trouble. And tell Imoen these words -- I suppose she won't listen, anyway. */
= @21 /* Go, I need to check something. (Gorion is holding a black tome with a grinning skull on the leather cover.) */
IF~~THEN REPLY @22 /* Thank you, father. Thank you for everything. I shall never forget you. */ GOTO ISNFGorion012
IF~~THEN REPLY @23 /* *Goodbye.* */ GOTO ISNFGorion013
END

IF~~THEN BEGIN ISNFGorion012
SAY @24 /* Hmm? That's very not like you. Go, my child. Play while you can. */
IF~~THEN DO ~SetGlobal("ISNFGorionMemory","GLOBAL",1) CreateVisualEffectObject("ISNFGo",Myself) ActionOverride(Player1,AddSpecialAbility("ISNFSP2")) DestroySelf()~ EXIT
END

IF~~THEN BEGIN ISNFGorion013
SAY @25 /* Goodbye, <CHARNAME>. */
IF~~THEN DO ~SetGlobal("ISNFGorionMemory","GLOBAL",1) CreateVisualEffectObject("ISNFGo",Myself) ActionOverride(Player1,AddSpecialAbility("ISNFSP1")) DestroySelf()~ EXIT
END

IF~~THEN BEGIN ISNFGorion007
SAY @26 /* ... */
= @27 /* ...Memories can't be rejected; they are your past... */
IF~~THEN DO ~SetGlobal("ISNFGorionMemory","GLOBAL",2)~ EXIT
END
