EXTEND_BOTTOM ~GOVWAU01~ 0
IF~Global("ISNFQuest","GLOBAL",1) Global("ISNFSune1","GLOBAL",0)~THEN REPLY @0 /* I have a question. Under what conditions can the dead be brought back to life? */ GOTO ISNFxDead000
END

APPEND ~GOVWAU01~
IF~~THEN BEGIN ISNFxDead000
SAY @1 /* Well, obviously you must have the corpse. It cannot be mutilated too badly or otherwise desecrated. Also, it generally works best if the body has not been dead a long time. That is all - everything else is just faith, and we've got plenty of that here. */
= @2 /* I feel I must ask however, if you're here on behalf of Orion... No need to look so surprised. He is known to us. But are you aware of what really happened? */
IF~~THEN REPLY @3 /* I think so... */ GOTO ISNFxDead001
IF~~THEN REPLY @4 /* He told me his story, though I'll admit I don't know all the details. */ GOTO ISNFxDead001
END

IF~~THEN BEGIN ISNFxDead001
SAY @5 /* I see. */
= @6 /* You are probably aware of the fact that he has been trying to find a way - not for days, but for weeks. I'm afraid that too much time has passed. No matter what would the state of her body be, it's just too late. */
= @7 /* But as you may know, he asked me some questions before. I tried to come up with a solution, but nothing came to mind. But since they loved each other that much, maybe the Sunites would know how to use that bond? */
IF~~THEN REPLY @8 /* The Sunites? I didn't know there was a Temple of Sune in Athkatla. */ GOTO ISNFxDead002
IF~InParty("YxYve")~THEN REPLY @9 /* I have a priestess of Sune in my group. */ GOTO ISNFxDead003
IF~!InParty("YxYve")~THEN REPLY @10 /* Do you know where I can find any Sunites? */ GOTO ISNFxDead002
END

IF~~THEN BEGIN ISNFxDead003
SAY @11 /* I don't want to offend your friend, but you may need someone with more experience. Someone older. */
IF~~THEN GOTO ISNFxDead002
END

IF~~THEN BEGIN ISNFxDead002
SAY @12 /* There is a man in Waukeen's promenade who may help you. He's a Sunite and those who praise Lady Firehair usually meet at his place. They even prepared an altar. They changed his estate into shrine. */
= @13 /* You can find him on the very north of the Promenade region, in an old looking orange building. */
= @14 /* But before you leave, take this piece of advice: I caution you to speak again with Orion. Sometimes the devil is in the details. */
IF~~THEN DO ~SetGlobal("ISNFSune1","GLOBAL",1)~ EXIT
END
END
