BEGIN ISNFxS1

//1 (window)


IF~Global("ISNFMemoryWindow","GLOBAL",0)~THEN BEGIN SeleneWind000
SAY @0 /* I'll never understand why you can't open a window from time to time, Orion. We both need to breathe, you know. Eh...it's stuck again. Can you help me? */
IF~~THEN REPLY @1 /* *Fine, fine. Although you know that I need to work. But I promise, we'll cook something together when I'm done with the research.* */ GOTO SeleneWind001
IF~~THEN REPLY @2 /* I'm not your husband and you're not Selene. You're just a memory that needs peace. */ GOTO SeleneWind00X
END

IF~~THEN BEGIN SeleneWind001
SAY @3 /* Oh, you always say that! But fine--you men are really horrible. And I swear, don't expect me to kiss you until you shave. (smiles and shows you a mirror) */
IF~~THEN REPLY @4 /* *For all the stars... when was the last time I--* */ GOTO SeleneWind002
IF~~THEN REPLY @5 /* It's not reflection of Orion. I'm not Orion. And you're nothing more but a ghost of the past. */ GOTO SeleneWind00X
END

IF~~THEN BEGIN SeleneWind002
SAY @6 /* It's been a week, "darling"! You really need a good shave and a warm bath. I'll prepare you one, so put down this book and let me help you before it's too late! Hehe. */
IF~~THEN REPLY @7 /* *Fine. But if I don't finish my work this month--* */ GOTO SeleneWind003
IF~~THEN REPLY @8 /* You're not Selene and I'm not Orion. Begone, vision of the past! */ GOTO SeleneWind00X
END

IF~~THEN BEGIN SeleneWind003
SAY @9 /* Oh, we both know you'll finish it. */
IF~~THEN REPLY @10 /* *You may be right.* */ GOTO SeleneWind004
IF~~THEN REPLY @11 /* And we both know this isn't your home, I'm not Orion. It's just a memory. */ GOTO SeleneWind00X
END

IF~~THEN BEGIN SeleneWind004
SAY @12 /* I AM right. Eh, you men are like babies. Just with bigger arms and with hair on your faces. (smiles) */
IF~~THEN DO ~SetGlobal("ISNFMemoryWindow","GLOBAL",1) AddexperienceParty(2000) CreateVisualEffectObject("ISNFGo",Myself) DestroySelf()~ EXIT
END

IF~~THEN BEGIN SeleneWind00X
SAY @13 /* What--what are--you... */
= @14 /* ...Memories can't be forgotten... */
IF~~THEN DO ~SetGlobal("ISNFMemoryWindow","GLOBAL",2) Enemy()~ EXIT
END

BEGIN ISNFxS2

//2 (telescope)

IF~Global("ISNFMemoryTele","GLOBAL",0)~THEN BEGIN SeleneTele000
SAY @15 /* ...I didn't want to damage it, really. */
IF~~THEN REPLY @16 /* *How many times have I asked you to stay away from it...* */ GOTO SeleneTele001
IF~~THEN REPLY @17 /* Begone, memory! I have no time for this. */ GOTO SeleneTele00X
END

IF~~THEN BEGIN SeleneTele001
SAY @18 /* --well, as many times as I asked you to open the window instead of pretending that we are fishes in a glass ball, darling. */
IF~~THEN REPLY @19 /* *You're just impossible.* */ GOTO SeleneTele003
IF~~THEN REPLY @20 /* I'm not going to pretend I'm Orion. Begone! */ GOTO SeleneTele00X
END

IF~~THEN BEGIN SeleneTele003
SAY @21 /* I hate when you pretend that I'm some kind of "girl" who can't help you or is unable to understand your work, Orion. It's so--so patronizing! */
IF~~THEN REPLY @22 /* *You know I didn't mean that!* */ GOTO SeleneTele004
IF~~THEN REPLY @23 /* You're not the real Selene. You're just a memory, Leave me. */ GOTO SeleneTele00X
END

IF~~THEN BEGIN SeleneTele004
SAY @24 /* So promise that you'll let me go next time. I want to be with my husband as a partner, not just as a "cheerful girl". */
IF~~THEN REPLY @25 /* *I know how skilled you are. And you're not just someone to cheer me up. You're much more, Selene.* */ GOTO SeleneTele005
IF~~THEN REPLY @26 /* Begone, memory. I'm fed up with all of this. */ GOTO SeleneTele00X
END

IF~~THEN BEGIN SeleneTele005
SAY @27 /* Good. */
= @28 /* Now forget about this scratch. We have so many other things to do. */
IF~~THEN DO ~SetGlobal("ISNFMemoryTele","GLOBAL",1) AddexperienceParty(2000) CreateVisualEffectObject("ISNFGo",Myself) DestroySelf()~ EXIT
END

IF~~THEN BEGIN SeleneTele00X
SAY @29 /* I--no... */
= @30 /* ...Memories can't perish... */
IF~~THEN DO ~SetGlobal("ISNFMemoryTele","GLOBAL",2) Enemy()~ EXIT
END

BEGIN ISNFxS3

//3 (desk)

IF~Global("ISNFMemoryDesk","GLOBAL",0)~THEN BEGIN SeleneDesk000
SAY @31 /* I prepared you something to drink. What are these notes about? */
IF~~THEN REPLY @32 /* *It's mostly about stars and their influence on Faerun. There are some dates here, you see.* */ GOTO SeleneDesk001
IF~~THEN REPLY @33 /* Go away. You're not real. */ GOTO SeleneDesk00X
END

IF~~THEN BEGIN SeleneDesk001
SAY @34 /* Well, I asked because I can see a mistake here. */
IF~~THEN REPLY @35 /* *What--?! Gods, you're right... this one is wrong. But...* */ GOTO SeleneDesk002
IF~~THEN REPLY @36 /* You are not real. You're not Selene. */ GOTO SeleneDesk00X
END

IF~~THEN BEGIN SeleneDesk002
SAY @37 /* Oh, I think you forgot that I'm not a usual housewife! */
IF~~THEN REPLY @38 /* *You're not, that's for sure.* */ GOTO SeleneDesk003
IF~~THEN REPLY @39 /* Leave me be, memory. I need to go. */ GOTO SeleneDesk00X
END

IF~~THEN BEGIN SeleneDesk003
SAY @40 /* Hehe, better remember that! */
IF~~THEN DO ~SetGlobal("ISNFMemoryDesk","GLOBAL",1) AddexperienceParty(2000) CreateVisualEffectObject("ISNFGo",Myself) DestroySelf()~ EXIT
END

IF~~THEN BEGIN SeleneDesk00X
SAY @41 /* I... */
= @42 /* ...I am the Color of Memory you shall never ignore... */
IF~~THEN DO ~SetGlobal("ISNFMemoryDesk","GLOBAL",2) Enemy()~ EXIT
END

BEGIN ISNFxS4

//4 (books)

IF~Global("ISNFMemoryBooks","GLOBAL",0)~THEN BEGIN SeleneBooks000
SAY @43 /* Oh, it's you... */
= @44 /* Have you seen my "Essences of the Weave"? I thought I left it on the shelf, but—where in the Nine Hells is that damn book! */
IF~~THEN REPLY @45 /* *Well, actually it's in front of you.* */ GOTO SeleneBooks001
IF~~THEN REPLY @46 /* You need to leave me, memory. */ GOTO SeleneBooks00X
END

IF~~THEN BEGIN SeleneBooks001
SAY @47 /* What--oh, you're right! But I would never put it here, next to "Joah and Signas". */
IF~~THEN REPLY @48 /* *I just had to check something.* */ GOTO SeleneBooks002
IF~~THEN REPLY @49 /* Begone, echo of the past. I'm done with you. */ GOTO SeleneBooks00X
END

IF~~THEN BEGIN SeleneBooks002
SAY @50 /* And you left it next to a romance book? Oh, Orion. You're always so organized, but when it comes to my books... */
= @51 /* But it doesn't matter. I have what I wanted. I need to prepare for our research. I think I may need to prepare some spells, too. We may need some light down there, or something to keep undead at a distance. */
IF~~THEN DO ~SetGlobal("ISNFMemoryBooks","GLOBAL",1) AddexperienceParty(2000) CreateVisualEffectObject("ISNFGo",Myself)DestroySelf()~ EXIT
END

IF~~THEN BEGIN SeleneBooks00X
SAY @52 /* ... */
= @53 /* ...Memories do not fade alone... */
IF~~THEN DO ~SetGlobal("ISNFMemoryBooks","GLOBAL",2) Enemy()~ EXIT
END

BEGIN ISNFxS5

//5 ("thing")

IF~Global("ISNFMemorything","GLOBAL",0)~THEN BEGIN SeleneThing000
SAY @54 /* Why is this thing standing in our bedroom...? */
IF~~THEN REPLY @55 /* *This is the "Mechanical Construct of the Stars". It should let me check some of the materials I gathered. If I succeed, then I'll have something to show to the man we have met some time go.* */ GOTO SeleneThing001
IF~~THEN REPLY @56 /* I am not the one you believe I am. I'm not Orion. Leave me. */ GOTO SeleneThing00X
END

IF~~THEN BEGIN SeleneThing001
SAY @57 /* And is this a reason why it's in the middle of the room we sleep in? Oh, Orion... */
IF~~THEN REPLY @58 /* *I really need it.* */ GOTO SeleneThing002
IF~~THEN REPLY @59 /* I don't have time for this. */ GOTO SeleneThing00X
END

IF~~THEN BEGIN SeleneThing002
SAY @60 /* ...I know... */
= @61 /* But I still hope that one day when I'm back home, I won't find here a dozen of... things like that and you in the center saying that you need to make sure that stars don't move. */
IF~~THEN REPLY @62 /* *I don't think so. I think we would rather move in a different place. (smile)* */ GOTO SeleneThing003
IF~~THEN REPLY @63 /* Go away. I'm not your husband. You're not Selene. Just a weak memory. */ GOTO SeleneThing00X
END

IF~~THEN BEGIN SeleneThing003
SAY @52 /* ... */
= @64 /* Oh you... you always know how to soften my heart. */
= @65 /* I think I'll go and focus on my own work. Let me know when you finish playing with your new gadget.. */
IF~~THEN DO ~SetGlobal("ISNFMemorything","GLOBAL",1) AddexperienceParty(2000) CreateVisualEffectObject("ISNFGo",Myself) DestroySelf()~ EXIT
END

IF~~THEN BEGIN SeleneThing00X
SAY @66 /* But... */
=@67 /* ...Memories do not leave. */
IF~~THEN DO ~SetGlobal("ISNFMemorything","GLOBAL",2) Enemy()~ EXIT
END

BEGIN ISNFxS6

//6 (bed)

IF~Global("ISNFMemoryBed","GLOBAL",0)~THEN BEGIN SeleneBed000
SAY @68 /* ...Do you think we will always be fine...? */
IF~~THEN REPLY @69 /* *We will.* */ GOTO SeleneBed001
IF~~THEN REPLY @70 /* Leave me, memory. I don't want to talk to you. */ GOTO SeleneBed00X
END

IF~~THEN BEGIN SeleneBed001
SAY @71 /* ...I have a feeling that the shadows got somehow deeper. More-- */
IF~~THEN DO ~SetGlobal("ISNFMemoryBed","GLOBAL",1) AddexperienceParty(2000) CreateVisualEffectObject("ISNFGo",Myself) DestroySelf()~ EXIT
END

IF~~THEN BEGIN SeleneBed00X
SAY @52 /* ... */
= @72 /* ...Memories never leave... */
IF~~THEN DO ~SetGlobal("ISNFMemoryBed","GLOBAL",2) Enemy()~ EXIT
END

BEGIN ISNFxS7

//7

IF~Global("ISNFMemoryCor","GLOBAL",0)~THEN BEGIN SeleneCorridor000
SAY @73 /* You are so close... now I see more and...you're not Orion... but someone else. */
= @74 /* Beware of the hooded souls… of the lost memories... */
IF~~THEN DO ~SetGlobal("ISNFMemoryCor","GLOBAL",1) CreateVisualEffectObject("ISNFGo",Myself) DestroySelf()~ EXIT
END

