APPEND ViconiP

IF WEIGHT #-25 ~Global("WQxViconia","GLOBAL",2)~THEN BEGIN WQxVicPrison000
SAY @0 /* By Shar, I should have cursed you, abbil, for letting this whore take me that easy! */
IF~~THEN REPLY @1 /* I'm sorry, Viconia. I didn't have any chance to stop her. */ GOTO WQxVicPrison001
IF~~THEN REPLY @2 /* So you're alive? I thought I'd rather find you dead. */ GOTO WQxVicPrison002
IF~~THEN REPLY @3 /* It is you who let her take you. I don't need someone so worthless in my group. It's too risky. */ GOTO WQxVicPrison003
END

IF~~THEN BEGIN WQxVicPrison001
SAY @4 /* I hope you're sorry. You call yourself a leader with such pathetic skills? That would have never happened if you would knew how to use your own strength. */
IF~~THEN GOTO WQxVicPrison004
END

IF~~THEN BEGIN WQxVicPrison002
SAY @5 /* Better watch your tongue, because it can be cut really easly. I'm not used to such dull jokes, so just try to keep silent in times like this. Silence is much better than dull words. */
IF~~THEN GOTO WQxVicPrison004
END

IF~~THEN BEGIN WQxVicPrison004
SAY @6 /* But that's enough. I won't scorn you for now, so just get me out of this filthy den, will you? */
IF~~THEN REPLY @7 /* Oh, as you wish, Black Queen. */ GOTO WQxVicPrison005
IF~~THEN REPLY @8 /* Before we leave, is everything alright? Did she do anything to you? */ GOTO WQxVicPrison006
IF~~THEN REPLY @9 /* Let's move from this dungeon. */ GOTO WQxVicPrison007
IF~~THEN REPLY @10 /* I don't need someone who can't even defend herself in my group. */ GOTO WQxVicPrison003
END

IF~~THEN BEGIN WQxVicPrison005
SAY @11 /* I warn you. Speak one more word in this manner and you can forget about my companionship. Are you really that fond of death? */
IF~~THEN REPLY @12 /* I'm sorry. I just couldn't resist, Viconia. */ GOTO WQxVicPrison008
IF~~THEN REPLY @13 /* I'm sorry. Before we move, tell me - are you alright? Did she do something to you? */ GOTO WQxVicPrison006
IF~~THEN REPLY @14 /* Leave then. I don't need someone who can't defend herself in situations like this one. */ GOTO WQxVicPrison003
END

IF~~THEN BEGIN WQxVicPrison008
SAY @15 /* You surfacers never cease annoying me. When I think you've already reached the bottom, you show me that you can be even more pathetic. */
IF~~THEN GOTO WQxVicPrison009
END

IF~~THEN BEGIN WQxVicPrison006
SAY @16 /* Did she do something? Isn't putting me in here humiliating enough? First those fanatics, then this whore. Shar, condamn their souls! */
IF~~THEN GOTO WQxVicPrison009
END

IF~~THEN BEGIN WQxVicPrison009
SAY @17 /* I hope corpse of this... insane keeper will rot here. She deserves nothing more but to become worm food. */
IF~~THEN REPLY @18 /* I am sure that is what's going to happen, Viconia. */ GOTO WQxVicPrison010
IF~~THEN REPLY @19 /* You're really vicious woman, you know? */ GOTO WQxVicPrison010
IF~~THEN REPLY @20 /* Interesting vision. */ GOTO WQxVicPrison010
END

IF~~THEN BEGIN WQxVicPrison010
SAY @21 /* Let's just end this blabbering and go! I don't want to see those walls any longer. */
IF~~THEN REPLY @22 /* You're right. Come, we should move on. */ GOTO WQxVicPrison007
IF~~THEN REPLY @23 /* I don't need someone who can't defend herself. Get lost, Viconia. */ GOTO WQxVicPrison003
END

IF~~THEN BEGIN WQxVicPrison007
SAY @24 /* At last you sound reasonable. That probably won't last long, though. */
IF~~THEN DO ~SetGlobal("WQxViconia","GLOBAL",3) JoinParty() AddXPObject(Player1,5000) AddXPObject("VICONIA",5000)~ EXIT
END

IF~~THEN BEGIN WQxVicPrison003
SAY @25 /* What?! After everything I've done for you, you just tell me to go?! I hope you die in those perilous swamps! */
IF~~THEN DO ~SetGlobal("WQxViconia","GLOBAL",3) AddXPObject(Player1,5000) EscapeArea()~ EXIT
END
END