BEGIN WQxT2

IF~Global("WQxTower2","GLOBAL",0)~THEN BEGIN WQxT200
SAY @0 /* So, you've almost reached the top. Tell me, why do you fight the Queen? */
IF~~THEN REPLY @1 /* Because she's a monster. She destroyed the village. */ GOTO WQxT201
IF~~THEN REPLY @2 /* Because I've already met demons and madmen in this place. No one who is any good would work with those. */ GOTO WQxT201
IF~~THEN REPLY @3 /* Honestly? This gives me a lot of new items and I need those to reach my own goal. */ GOTO WQxT201
IF~~THEN REPLY @4 /* I was asked to do that. The last survivor from the village told me what the Queen and her necromancer did. */ GOTO WQxT201
IF~~THEN REPLY @5 /* I won't give you my reason. */ GOTO WQxT201
END

IF~~THEN BEGIN WQxT201
SAY @6 /* I see. */
=
@7 /* I've always believed that one should never get involved before he or she knows the whole story. The truth is that you know very little. If you've got those ideas on the way here, then you've never talked to Queen. You haven't seen her eyes. They have cried oceans of tears. */
IF~~THEN REPLY @8 /* Fact that she cried doesn't mean she's innocent. */ GOTO WQxT202
IF~~THEN REPLY @9 /* So maybe her loss took her sanity. That's possible. */ GOTO WQxT202
IF~~THEN REPLY @10 /* I want to talk to her. */ GOTO WQxT202
END

IF~~THEN BEGIN WQxT202
SAY @11 /* Are going to kill her, then? */
IF~~THEN REPLY @12 /* I don't know yet. */ GOTO WQxT203
IF~~THEN REPLY @13 /* Yes. She is too dangerous to live. */ GOTO WQxT204
IF~~THEN REPLY @14 /* No, if she appears to be sane. */ GOTO WQxT205
END

IF~~THEN BEGIN WQxT203
SAY @15 /* You don't know? Heh, that's funny. You killed all her servants on the stairs up to her tower and you believe there is a chance to let her live. You're really cruel. */
IF~~THEN GOTO WQxT206
END

IF~~THEN BEGIN WQxT204
SAY @16 /* She's too dangerous, you say. You - <PRO_RACE> who killed all those who were on the stairs up to this very chamber. You're a true hypocrite. */
IF~~THEN GOTO WQxT206
END

IF~~THEN BEGIN WQxT205
SAY @17 /* As I thought. You are going to kill her - I don't believe you will consider everything that happened to be "sane". You just try to use words that would sound better. */
IF~~THEN GOTO WQxT206
END

IF~~THEN BEGIN WQxT206
SAY @18 /* I can tell you that once you go upstairs, she won't let you leave as long as one of you is alive. She will consider you an intruder who tries to kill the peace she wants to reach. */
=
@19 /* You know, maybe she actually seeks death? Maybe only death can offer her the silence and the whiteness she desires. I don't know. */
=
@20 /* But I know that no matter what you're going to do up there, you must first pass through me. I promised to stay by her side until the very end and I do not break my promises. */
IF~~THEN REPLY @21 /* It's sad that I must fight such a loyal person. */ GOTO WQxT207
IF~~THEN REPLY @22 /* If you wish to die, so be it. */ GOTO WQxT208
END

IF~~THEN BEGIN WQxT207
SAY @23 /* Thank you. We should start the fight. To me, my friends! We will protect our Queen! */
IF~~THEN DO ~SetGlobal("WQxTower2","GLOBAL",1) Enemy()~ EXIT
END

IF~~THEN BEGIN WQxT208
SAY @24 /* To me, my friends! We will protect our Queen! */
IF~~THEN DO ~SetGlobal("WQxTower2","GLOBAL",1) Enemy()~ EXIT
END