BEGIN WQxWQ

IF~Global("WQxMainQuest","GLOBAL",8)~THEN BEGIN WQxWQ000
SAY @0 /* Whitness is so pure, so calm, but yet... it seems that it has been tainted. Who are you? This is my personal space. There should be no...intruders in here. */
IF~~THEN REPLY @1 /* Very unusual beginning of a conversation. It's surprising that the first thing you ask about is my name. */ GOTO WQxWQ001x
IF~~THEN REPLY @2 /* I am <CHARNAME>. */ GOTO WQxWQ001
IF~~THEN REPLY @3 /* I am a Bhaalspawn. */ GOTO WQxWQ002
IF~~THEN REPLY @4 /* I won't tell you my name. */ GOTO WQxWQ003
END

IF~~THEN BEGIN WQxWQ001x
SAY @5 /* Really? I thought it would be normal. Isn't that what people usually do? So, what is it? */
IF~~THEN REPLY @6 /* Fine. I am <CHARNAME>. */ GOTO WQxWQ001
IF~~THEN REPLY @7 /* I am a Bhaalspawn, that should be more than enough. */ GOTO WQxWQ002
IF~~THEN REPLY @8 /* I won't tell you my name, Queen. */ GOTO WQxWQ003
END

IF~~THEN BEGIN WQxWQ001
SAY @9 /* <CHARNAME>... that seems to be a nice name. */
IF~~THEN GOTO WQxWQ004
END

IF~~THEN BEGIN WQxWQ002
SAY @10 /* A Bhaalspawn? Your heritage doesn't matter. I asked for your name - that's how any relationship usually starts. */
IF~~THEN REPLY @11 /* My name is <CHARNAME>. */ GOTO WQxWQ001
IF~~THEN REPLY @4 /* I won't tell you my name. */ GOTO WQxWQ003
END

IF~~THEN BEGIN WQxWQ003
SAY @12 /* A pity, but it is your right. Everyone has a right to withhold his or her name. */
IF~~THEN GOTO WQxWQ004
END

IF~~THEN BEGIN WQxWQ004
SAY @13 /* Now, I see you do not wear white, so you're not a new servant. Tell me, why do you stand here before me? I find it surprising that my servants let you in just like that. */
IF~~THEN REPLY @14 /* I was sent by one of the villagers. I'm here to kill you. */ GOTO WQxWQ005
IF~~THEN REPLY @15 /* A villager sent me to kill you, but I'd like to talk to you first. */ GOTO WQxWQ005
IF~~THEN REPLY @16 /* Even though in the beginning I was sent by a villager, I think I've lost my reason on the way here. */ GOTO WQxWQ005
END

IF~~THEN BEGIN WQxWQ005
SAY @17 /* A villager?! So there is someone left in the village? Those filthy villains. I can never forgive them! Why did you mention them? My lightheartedness, my tranquility, they are leaving me. I thought the villagers were all dead, but now... are you always such a messenger of devilry? */
IF~~THEN REPLY @18 /* You killed them all along with your brother - necromancer. It is *them* who should hate *you*. */ GOTO WQxWQ006
IF~~THEN REPLY @19 /* Why are you so angry with them? I know something has happened, but I think it would be good to know what really happened from you. */ GOTO WQxWQ007
IF~~THEN REPLY @20 /* Haha! You're such a funny woman. You are angry? You slaughtered them! */ GOTO WQxWQ006
IF~~THEN REPLY @21 /* Look, I think they did something to you. I want to hear the whole story, if you don't mind. */ GOTO WQxWQ007
END

IF~~THEN BEGIN WQxWQ006
SAY @22 /* How dare you?! You have no idea what are you in, do you? */
IF~~THEN GOTO WQxWQ008
END

IF~~THEN BEGIN WQxWQ007
SAY @23 /* You want to hear it? Didn't your "employer" tell you what it's all about? */
IF~~THEN GOTO WQxWQ008
END

IF~~THEN BEGIN WQxWQ008
SAY @24 /* We are having a duel. I won't reach my beloved peace until all of them are dead. I had a feeling that there was someone left and now I know who. That heartless druid! It must be him, you don't even have to answer. */
=
@25 /* Just as I won't rest until they are dead, he won't stop until I and my followers are dead. He's feeding on my pain, can't you see it? Why do you think he keeps returning to this place over and over and over again? That black-hearted villain! */
IF~~THEN REPLY @26 /* But why this, as you call it, duel started? There must be a reason! */ GOTO WQxWQ009
IF~~THEN REPLY @27 /* You tell me that I was used by him? */ GOTO WQxWQ010
IF~~THEN REPLY @28 /* But what are you two fighting for? */ GOTO WQxWQ009
IF~~THEN REPLY @29 /* Oh, marvelous! When I just get him into my hands, I shall kill him! No one can use <CHARNAME>! */ GOTO WQxWQ010
END

IF~~THEN BEGIN WQxWQ009
SAY @30 /* It started so long time ago, but the memories are still so vivid... */
IF~~THEN GOTO WQxWQ011
END

IF~~THEN BEGIN WQxWQ010
SAY @31 /* You're not the first ones used by this horrible person. */
IF~~THEN GOTO WQxWQ011
END

IF~~THEN BEGIN WQxWQ011
SAY @32 /* Everything started when I was still Countess Celine Shalloweye, because they felt I was a worthless ruler. Of course, some of my decisions could have been better, but I did all I could to protect the village. However, when cold times started, one family died. They blamed me, but even now I have no idea how I could have helped them. They didn't even tell me that their situation was that difficult. */
=
@33 /* But that was the trigger for the one you met. He started a rebellion against me. He believed that he would be a better ruler of the swamps. He searched for a way to persuade them, so he decided to study the creatures of the swamps. */
IF~~THEN REPLY @34 /* How? */ GOTO WQxWQ012
IF~~THEN REPLY @35 /* Continue, please. */ GOTO WQxWQ012
END

IF~~THEN BEGIN WQxWQ012
SAY @36 /* He took my baby and offered her to a green hag, the most respected being by all the spiders, slimes and snakes that live here in Silent Swamps. She took her and disappeared. Forever. */
=
@37 /* You can't imagine how I felt! A ruler who didn't realize that a family was dying! A mother who had lost her child! */
=
@38 /* But they... they all followed this...demon! Followed the damned druid! He was nothing more but the most treacherous creature in the whole land! I can never forgive them! I can never forgive him, who took my child from me! */
IF~~THEN REPLY @39 /* So that's why your brother came, yes? */ GOTO WQxWQ013
IF~~THEN REPLY @40 /* Then the necromancer came? */ GOTO WQxWQ013
IF~~THEN REPLY @41 /* What happened next? */ GOTO WQxWQ014
END

IF~~THEN BEGIN WQxWQ013
SAY @42 /* Yes. */
IF~~THEN GOTO WQxWQ014
END

IF~~THEN BEGIN WQxWQ014
SAY @43 /* My brother helped me. He always had talent when it come to magic, especially necromancy. I wanted to take their lives as they took the life I had bore. I have got their lifeforce inside of me thanks to what Rodian did. */
IF~~THEN REPLY @44 /* But maybe your child is alive? */ GOTO WQxWQ015
IF~~THEN REPLY @45 /* Did you try to look for your baby? */ GOTO WQxWQ016
IF~~THEN REPLY @46 /* But they took one life and you took at least a dozen! */ GOTO WQxWQ017
END

IF~~THEN BEGIN WQxWQ015
SAY @47 /* No, she's not. */
IF~~THEN GOTO WQxWQ018
END

IF~~THEN BEGIN WQxWQ016
SAY @48 /* Isn't that obvious? */
IF~~THEN GOTO WQxWQ018
END

IF~~THEN BEGIN WQxWQ018
SAY @49 /* Brother helped me to organize a search. We found it dead. Hag used it as a component for its own magic! All I got back was a small, silver chain my child had on the wrist. */
IF~~THEN GOTO WQxWQ019
END

IF~~THEN BEGIN WQxWQ017
SAY @50 /* Yes, to make sure every single villager will realize how much my pain was. They suffered, they felt their life draining away from the body along with their blood. They could feel the loss I experienced. How I felt when my brother found the silver chain on a child's body in the forest. My child's body... */
IF~~THEN GOTO WQxWQ019
END

IF~~THEN BEGIN WQxWQ019
SAY @51 /* Now, it's just me and that filthy druid. All the others are gone. You know, I wish it could end tomorrow. It is always good to know that tomorrow will be a good day, quite different without his presence. */
=
@52 /* Now, after this talk I understand that Whiteness can give me no more tranquility. But I don't blame you on my loss. At least I could share my sorrow with someone. */
=
@53 /* However, I must tell you that even if you want to kill me, my brother's ritual made me somehow resistant to death. The Gods of Death themselves have neglected me. */
IF~~THEN REPLY @54 /* I may know the way to end this. The tree from the village was blessed by priest of Kelemvor long time ago. It can probably end your life. */ GOTO WQxWQ020
IF~~THEN REPLY @55 /* I still want to try. I will try until I succeed in defeating you. */ GOTO WQxWQ021
END

IF~~THEN BEGIN WQxWQ020
SAY @56 /* Blessed by Kelemvor? I didn't know that. But maybe it was just prepared by the hag? But I think it doesn't matter. */
IF~~THEN GOTO WQxWQ022
END

IF~~THEN BEGIN WQxWQ021
SAY @57 /* Try then. */
IF~~THEN GOTO WQxWQ022
END

IF~~THEN BEGIN WQxWQ022
SAY @58 /* I want this death, without you this war may never end, but please, don't let him go. Defeat the druid. Do the same with the hag if you find her. I beg you. */
IF~~THEN REPLY @59 /* I will consider it. */ GOTO WQxWQ023
IF~~THEN REPLY @60 /* Just die already. */ GOTO WQxWQ024
IF~~THEN REPLY @61 /* I will. He used me, too. */ GOTO WQxWQ023
END

IF~~THEN BEGIN WQxWQ023
SAY @62 /* Thank you. */
IF~~THEN DO ~SetGlobal("WQxMainQuest","GLOBAL",9) Enemy()~ EXIT
END

IF~~THEN BEGIN WQxWQ024
SAY @63 /* Face me, then. */
IF~~THEN DO ~SetGlobal("WQxMainQuest","GLOBAL",9) Enemy()~ EXIT
END

