BEGIN WQxKEE

////Usual

IF~Global("WQxKeeper","GLOBAL",0)~THEN BEGIN WQxKEE000
SAY @0 /* So you're eventually here? I won't let you free those who are opposed to calm whiteness. Can't you understand it? I am the Keeper here and I can't let it happen. */
IF~~THEN REPLY @1 /* You are mad! */ GOTO WQxKEE001
IF~GlobalGT("WQxViconia","GLOBAL",0)~THEN REPLY @2 /* I don't want anyone to suffer! Just give me back my companion! */ GOTO WQxKEE002
IF~~THEN REPLY @3 /* I won't let you imprison people just because you decided to follow the White Queen. */ GOTO WQxKEE003 
IF~~THEN REPLY @4 /* Listen, I don't want anyone to suffer! */ GOTO WQxKEE002
END

IF~~THEN BEGIN WQxKEE001
SAY @5 /* I'm not mad. The village itself is mad! The villagers. It's their fault. You shall join their bodies in the waters of this swamp! */
IF~~THEN DO ~SetGlobal("WQxKeeper","GLOBAL",1) Enemy()~ EXIT
END

IF~~THEN BEGIN WQxKEE002
SAY @6 /* Suffer? You don't know what it means to suffer. The White Queen knows. */
=
@7 /* I will end your life! You shall join the other bodies in the waters of this swamp! */
IF~~THEN DO ~SetGlobal("WQxKeeper","GLOBAL",1) Enemy()~ EXIT
END

IF~~THEN BEGIN WQxKEE003
SAY @8 /* Do what you must, but I will not let you take me or my Queen! She has suffered enough pain. */
IF~~THEN DO ~SetGlobal("WQxKeeper","GLOBAL",1) Enemy()~ EXIT
END

////Kidnapping

CHAIN IF ~Exists("WQxKEE") InParty("Viconia") Dead("WQxIENT") CombatCounter(0) Global("WQxViconia","GLOBAL",0)~ THEN ViconiJ ViconWQ000
@9 /* Another dirty place filled with fools. I will never understand why you, abbil, always bother with issues which don't concern you. It's mostly... */
=
@10 /* Wait! We are not alone. */
==WQxKEE
@11 /* How can such a filthy black creature like you enter the palace of White Queen?! I heard that women in black came here to fight our mistress! I shall not let it happen! */
==ViconiJ
@12 /* Pathetic girl, do you really think you can resist me and Shar? Look, some of your companions are already dead. Get out of our way if you don't want to join them. We have no time for an iblith as you. */
==WQxKEE
@13 /* Since there is a White Queen, you must be the Black One. It's my duty to stop you. You will come with me, Black Queen - you have no other choice! You can't disturb the one I serve! */
==ViconiJ
@14 /* Nau! Shar! Abbil! Don't let her take... */
==WQxKEE
@15 /* It's too late, Black Queen! */
DO ~SetGlobal("WQxViconia","GLOBAL",1)~
EXIT