BEGIN WQxPRI

IF~Global("WQxPrisoner","GLOBAL",0)~THEN BEGIN WQxPRI000
SAY @0 /* No... please... leave me... */
=
@1 /* Wait, you're not one of them. Who are you? */
IF~~THEN REPLY @2 /* I am here to stop the insane tyranny of the White Queen. Who are you? */ GOTO WQxPRI001
IF~~THEN REPLY @3 /* It doesn't matter. Better tell me who are you. */ GOTO WQxPRI001
IF~~THEN REPLY @4 /* I'm not here to discuss. You're wearing white robes, so you are my enemy. Die. */ GOTO WQxPRI002
END

IF~~THEN BEGIN WQxPRI001
SAY @5 /* I am Selence Rubyshore. I used to be one of the servants. I joined them later than most of the most loyal servants, I was an adventurer who found this place. When I was caught, I promised to work for White Queen. */
=
@6 /* I didn't want to stay here forever, but the moment I tried to leave palace, I was stopped by the Keeper. Look out, she's really strong. */
IF~~THEN REPLY @7 /* Could you tell me something about the White Queen? */ GOTO WQxPRI003
IF~~THEN REPLY @8 /* Tell me something about the White Keeper. */ GOTO WQxPRI003
IF~~THEN REPLY @9 /* Run. Maybe you'll find a way out. Most of servants are dead. */ GOTO WQxPRI004
IF~~THEN REPLY @10 /* You're wearing white robes, so you are my enemy. Die. */ GOTO WQxPRI002
END

IF~~THEN BEGIN WQxPRI003
SAY @11 /* I will tell you about both Queen and Keeper. */
=
@12 /* As I told you, I can't tell too much, because I wasn't here when it happened, but I think White Queen lost a kin here, in these swamps. That's the same way the Keeper lost a child. The Keeper is the most trusted of the Queen's followers, because she knows what it's like to lose someone close. */
=
@13 /* They are very alike, but the Keeper is more harsh and brutal. All the Queen wants is peace of mind, while the Keeper tries to change everything, she destroys everything that stands in her way. */
=
@14 /* She's unpredictable. */
IF~~THEN REPLY @15 /* Thank you for telling me all of this. Run. Maybe you'll find a way out. */ GOTO WQxPRI004
IF~~THEN REPLY @16 /* Is she somewhere here? */ GOTO WQxPRI005
IF~~THEN REPLY @17 /* Now I will kill you. I don't want anyone to leave this place alive. I believe you all lie, anyway. */ GOTO WQxPRI002
END

IF~~THEN BEGIN WQxPRI005
SAY @18 /* Yes, she's deeper in the tunnel. Look out, she has some kind of... white wolves with her. */
IF~~THEN REPLY @19 /* Thank you for telling me everything. Run. Maybe you'll find a way out. */ GOTO WQxPRI004
IF~~THEN REPLY @20 /* Now I will kill you. I don't want anyone to leave this place alive. Thanks anyway. */ GOTO WQxPRI002
END

IF~~THEN BEGIN WQxPRI004
SAY @21 /* Thank you! I know the way! */
IF~~THEN DO ~SetGlobal("WQxPrisoner","GLOBAL",1) AddexperienceParty(6000) EscapeArea()~ EXIT
END

IF~~THEN BEGIN WQxPRI002
SAY @22 /* Aaaaa! No! */
IF~~THEN DO ~SetGlobal("WQxPrisoner","GLOBAL",1) Enemy()~ EXIT
END