APPEND KELDORJ

IF WEIGHT #-25 ~Global("WQxKeldorn","GLOBAL",0) Dead("WQxDem") AreaCheck("WQ0004")~ THEN BEGIN WQxKeld000
SAY @0 /* I value the fact that you didn't make any deal with the demon. I am sure he would have tricked us in the end. */
IF~~THEN REPLY @1 /* I've met enough demons in my life to know that, Keldorn. */ GOTO WQxKeld001
IF~~THEN REPLY @2 /* No worries, I do not trust every creature I meet on the road. That could have been a trap. */ GOTO WQxKeld002
IF~~THEN REPLY @3 /* We have no time for talks right now. Let us move on, Keldorn. */ GOTO WQxKeld003
END

IF~~THEN BEGIN WQxKeld001
SAY @4 /* Experience serve us well, then. */
IF~~THEN GOTO WQxKeld004
END

IF~~THEN BEGIN WQxKeld002
SAY @5 /* Indeed. You are a wise <PRO_MANWOMAN>, then. */
IF~~THEN GOTO WQxKeld004
END

IF~~THEN BEGIN WQxKeld004
SAY @6 /* I worry what kind of enemies we're going to face in this palace. We've seen those servants, we've seen undead outside. The deeper we go, the greater malice we may meet. */
IF~~THEN REPLY @7 /* I'm not really sure. There's something strange happening here. This demon wasn't free and those people don't seem to be really vicious, too. */ GOTO WQxKeld005
IF~~THEN REPLY @8 /* I know. I hope that we can get to this White Queen soon enough to stop madness that is happening all around this place. */ GOTO WQxKeld006
IF~~THEN REPLY @9 /* I'm aware of that. Let us move on, Keldorn. */ GOTO WQxKeld003
END

IF~~THEN BEGIN WQxKeld005
SAY @10 /* I see. There may be something, but remember not to fall into their trap. This may be their game to make you believe the White Queen isn't our enemy. */
IF~~THEN GOTO WQxKeld007
END

IF~~THEN BEGIN WQxKeld006
SAY @11 /* Finding the Queen may be the way, but we should keep in mind that even then someone may carry out her plan. We still know very little about what's actually happening. */
IF~~THEN GOTO WQxKeld007
END

IF~~THEN BEGIN WQxKeld007
SAY @12 /* Are you willing to talk with this Queen? */
IF~~THEN REPLY @13 /* Yes, I think so. */ GOTO WQxKeld008
IF~~THEN REPLY @14 /* I'm not sure. She'll probably just tell us some lies. */ GOTO WQxKeld009
IF~~THEN REPLY @15 /* It doesn't matter. Can we just move on? */ GOTO WQxKeld003
END

IF~~THEN BEGIN WQxKeld008
SAY @16 /* Fine. I'd like to know what's the reason for all of this. Since we'll both be there, we won't be easly misled. */
IF~~THEN DO ~SetGlobal("WQxKeldorn","GLOBAL",1)~ EXIT
END

IF~~THEN BEGIN WQxKeld009
SAY @17 /* Maybe, but still we should still listen to her. Since we'll both be there, we won't be easly misled. */
IF~~THEN DO ~SetGlobal("WQxKeldorn","GLOBAL",1)~ EXIT
END

IF~~THEN BEGIN WQxKeld003
SAY @18 /* Right then. We shall reach the heart of this matter. */
IF~~THEN DO ~SetGlobal("WQxKeldorn","GLOBAL",1)~ EXIT
END
END

APPEND NaliaJ

IF WEIGHT #-25 ~Global("WQxNalia","GLOBAL",0) Dead("WQxWQ") AreaCheck("WQ0008")~ THEN BEGIN WQxNalia000
SAY @19 /* She...she's dead now. I hope she will find the tranquility she wished for. I really hope so. */
IF~~THEN REPLY @20 /* Is something wrong, Nalia? You seem troubled. */ GOTO WQxNalia001
IF~~THEN REPLY @21 /* Yes, and I'd rather leave this place. We should move on. */ GOTO WQxNalia002
END

IF~~THEN BEGIN WQxNalia001
SAY @22 /* It's because I somehow understand her feelings. She wanted to get some peace and silence after those she cared for killed her child. I started to think what I would do if I were on her place. This must have been so painful for her... */
IF~~THEN REPLY @23 /* As painful as losing your father, yes? */ GOTO WQxNalia003
IF~~THEN REPLY @24 /* I think I understand where this is going. Nalia, your father wasn't killed by the one he cared for. */ GOTO WQxNalia004
IF~~THEN REPLY @25 /* We have no time for this. We should move on. */ GOTO WQxNalia002
IF~~THEN REPLY @26 /* I think I don't get it. Why are you so sympathetic out of the blue? */ GOTO WQxNalia005
END

IF~~THEN BEGIN WQxNalia003
SAY @27 /* It seems you know me well, <CHARNAME>. When I imagine how it would be if I lost him because of one of his men... */
IF~~THEN GOTO WQxNalia006
END

IF~~THEN BEGIN WQxNalia004
SAY @28 /* Yes, but if I suffered that much when my father was killed by a troll, what would it be like if he was killed by one of his people? By one of *my* people. */
IF~~THEN GOTO WQxNalia006
END

IF~~THEN BEGIN WQxNalia005
SAY @29 /* You know what happened to my father. I suffered that much when my father was killed by a troll, so what it would be if he was killed by one of his people? By one of *my* people. */
IF~~THEN GOTO WQxNalia006
END

IF~~THEN BEGIN WQxNalia006
SAY @30 /* This is a truly horrible vision. I know I shouldn't think of it, but... */
=
@31 /* I just pity her. I feel she could be someone simillar to me before that happened. What if... */
IF~~THEN REPLY @32 /* If what? */ GOTO WQxNalia007
IF~~THEN REPLY @33 /* What is it? Just say it loud. */ GOTO WQxNalia007
IF~~THEN REPLY @34 /* I think we should move on. We have no time for that kind of trouble, Nalia. */ GOTO WQxNalia002
END

IF~~THEN BEGIN WQxNalia007
SAY @35 /* I'm just afraid that I may become like her one day. That I could change if those my family who survived were killed by my... I just can't even think of it! */
=
@36 /* But I feel I could become another White Queen if I had her experience. */
IF~~THEN REPLY @37 /* Anyone could, Nalia. Losing a child must really be something quite overwhelming. */ GOTO WQxNalia008
IF~~THEN REPLY @38 /* Nalia, please... */ GOTO WQxNalia008
IF~~THEN REPLY @39 /* You're getting too emotional. Calm down, will you? */ GOTO WQxNalia008
IF~~THEN REPLY @40 /* We have no time for this! Let us move on! */ GOTO WQxNalia002
END

IF~~THEN BEGIN WQxNalia008
SAY @41 /* I just can't help it. Look, even my hands are shaking... */
IF~~THEN REPLY @42 /* Come. You must leave this place. */ GOTO WQxNalia009
IF~~THEN REPLY @43 /* Take a deep breath. Everything is alright. I'm here. */ GOTO WQxNalia009
IF~~THEN REPLY @44 /* Just stow it and let us go. */ GOTO WQxNalia002
END

IF~~THEN BEGIN WQxNalia009
SAY @45 /* I think I'll be fine as soon as we leave the palace. I'm really sorry for this...delay I forced. */
IF~~THEN DO ~SetGlobal("WQxNalia","GLOBAL",1)~ EXIT
END

IF~~THEN BEGIN WQxNalia002
SAY @46 /* Let's just leave this place. I think I don't want to see anything white for a while... */
IF~~THEN DO ~SetGlobal("WQxNalia","GLOBAL",1)~ EXIT
END
END

APPEND CerndJ

IF WEIGHT #-25 ~Global("WQxCernd","GLOBAL",0) Dead("WQxTRE") AreaCheck("WQ0001")~ THEN BEGIN WQxCernd000
SAY @47 /* Do you think this man deserved to die? */
IF~~THEN REPLY @48 /* Don't tell me you're on his side! */ GOTO WQxCernd001
IF~~THEN REPLY @49 /* He made a contract with hag to have revenge. He deserved to die, Cernd. */ GOTO WQxCernd002
IF~~THEN REPLY @50 /* I'm not sure, but I am afraid he wouldn't stop. */ GOTO WQxCernd003
IF~~THEN REPLY @51 /* Just let us go, Cernd. */ GOTO WQxCernd004
END

IF~~THEN BEGIN WQxCernd001
SAY @52 /* I'm just asking. */
IF~~THEN REPLY @53 /* He made a contract with hag to have revenge, so yes, he deserved to die. */ GOTO WQxCernd002
IF~~THEN REPLY @54 /* I'm not sure if he deserved that, but I am afraid he wouldn't stop. */ GOTO WQxCernd003
IF~~THEN REPLY @55 /* Your question is pointless. Just let us go, Cernd. */ GOTO WQxCernd004
END

IF~~THEN BEGIN WQxCernd002
SAY @56 /* It's really easy to judge other people. */
IF~~THEN GOTO WQxCernd005
END

IF~~THEN BEGIN WQxCernd003
SAY @57 /* I see, but I suppose we can't be sure of that. */
IF~~THEN GOTO WQxCernd005
END

IF~~THEN BEGIN WQxCernd005
SAY @58 /* I somehow believe that he broke the rules when he used human life as a currency. That was something beyond the law. */
IF~~THEN REPLY @59 /* You seem strange. */ GOTO WQxCernd006
IF~~THEN REPLY @60 /* Is everything alright, Cernd? */ GOTO WQxCernd006
IF~~THEN REPLY @61 /* You're right. */ GOTO WQxCernd007
IF~~THEN REPLY @62 /* I think we should move on, Cernd. There is still some work to do. */ GOTO WQxCernd004
END

IF~~THEN BEGIN WQxCernd006
SAY @63 /* I'm sorry if my question troubled you. I thought asking you about it would be fine. */
IF~~THEN GOTO WQxCernd008
END

IF~~THEN BEGIN WQxCernd007
SAY @64 /* I'm glad we do agree. */
IF~~THEN GOTO WQxCernd008
END

IF~~THEN BEGIN WQxCernd008
SAY @65 /* I suppose he was the one we druids would call 'avenger', but a very self-confident one. Even though he still had a strong link to the nature, he used it to fight humans. He had something in common with Faldorn. */
IF~~THEN REPLY @66 /* I think I know what you mean and that wouldn't be horrible nails. */ GOTO WQxCernd009
IF~~THEN REPLY @67 /* He was blinded by his own beliefs. I'm not sure if it had anything to do with nature. */ GOTO WQxCernd010
IF~~THEN REPLY @68 /* Just let us go, Cernd. We have work to do. */ GOTO WQxCernd004
END

IF~~THEN BEGIN WQxCernd009
SAY @69 /* Before they seek balance in nature and people, they should have found it inside themselves, first. */
IF~~THEN DO ~~ EXIT
END

IF~~THEN BEGIN WQxCernd010
SAY @70 /* Still, he offered the sacrifice to the swamps, not to other people. */
=
@71 /* But I'm not here to make any excuses for him. Maybe now these swamps will regain the balance. */
IF~~THEN DO ~SetGlobal("WQxCernd","GLOBAL",1)~ EXIT
END

IF~~THEN BEGIN WQxCernd004
SAY @72 /* Lead then, <CHARNAME>. */
IF~~THEN DO ~SetGlobal("WQxCernd","GLOBAL",1)~ EXIT
END
END