BEGIN WQxDEM

//////First Talk

IF~Global("WQxDemon","GLOBAL",0)~THEN BEGIN Demon000
SAY @0 /* Ah, you must be the one who made all this noise! If it wasn't the mage who is probably going to lose, I would try to get your head, Bhaalspawn. Even though I'm bound. */
IF~~THEN REPLY @1 /* How do you know that I'm a Bhaalspawn? */ GOTO Demon001
IF~~THEN REPLY @2 /* A demon, here? Ha, good riddance! */ GOTO Demon002
IF~~THEN REPLY @3 /* What are you doing here? */ GOTO Demon003
END

IF~~THEN BEGIN Demon001
SAY @4 /* I can tell that thanks to the metallic scent you have. Much deeper and much more vivid that of any other <PRO_RACE>. */
IF~~THEN GOTO Demon004
END

IF~~THEN BEGIN Demon002
SAY @5 /* It seem that you're not really afraid of me. That's quite a rare attitude. */
IF~~THEN GOTO Demon004
END

IF~~THEN BEGIN Demon003
SAY @6 /* It seems you rapidly get to the point, <PRO_RACE>. How typical. */
IF~~THEN GOTO Demon004
END

IF~~THEN BEGIN Demon004
SAY @7 /* You can surely guess that I'm not going to give you my name, but I can tell you who brought me to this filthy den. The necromancer. Yes, the one who started the phase that is happening here. The one who works with the White Queen. */
=
@8 /* Even though I'm bound, I still have my eyes and ears. I can smell odour of his body next to this chamber. So, do you wish some help? Do you want to make a deal? A fair one. */
IF~~THEN REPLY @9 /* What do you mean? */ GOTO Demon005
IF~~THEN REPLY @10 /* A fair deal with a demon? You're funny, you know? */ GOTO Demon006
IF~~THEN REPLY @11 /* I do not trade with dark creatures like you! */ GOTO Demon007
END

IF~~THEN BEGIN Demon005
SAY @12 /* So you're interested? Exquisite. */
IF~~THEN GOTO Demon008
END

IF~~THEN BEGIN Demon006
SAY @13 /* Laugh, if you want to. That won't harm us, but still I'm going to present my offert. */
IF~~THEN GOTO Demon008
END

IF~~THEN BEGIN Demon007
SAY @14 /* But listening doesn't mean you're trading, Bhaalspawn. */
IF~~THEN GOTO Demon008
END

IF~~THEN BEGIN Demon008
SAY @15 /* Bring me head of this necromancer and in exchange you shall get help. You will be able to decide what kind of...currency you're interested in. */
IF~~THEN REPLY @16 /* No way. When the deal is over, you'll surely jump to get my head too. */ GOTO Demon009
IF~~THEN REPLY @17 /* Sounds interesting. This may be a good idea, actually. */ GOTO Demon010
END

IF~~THEN BEGIN Demon009
SAY @18 /* Ha! I've seen better heads than yours. I don't need you Bhaalspawn, don't be so egocentric. */
IF~~THEN GOTO Demon011
END

IF~~THEN BEGIN Demon010
SAY @19 /* So you're a merchant inside! How fortunate. */
IF~~THEN GOTO Demon011
END

IF~~THEN BEGIN Demon011
SAY @20 /* You don't have to give me answer now. Just bring me the head, that's all. */
IF~~THEN REPLY @21 /* What are you going to do when you're free? */ GOTO Demon012
IF~~THEN REPLY @22 /* No. I shall end your life now! */ GOTO Demon013
IF~~THEN REPLY @23 /* No. I'm leaving. */ GOTO Demon014
IF~~THEN REPLY @24 /* I'll bring you the head. */ GOTO Demon015
END

IF~~THEN BEGIN Demon012
SAY @25 /* Isn't it obvious? */
=
@26 /* I will find a prey that will be able to satiate my desires. That would be surely away from this part of Faerun, so no need to worry about yourself, Bhaalspawn. */
IF~~THEN REPLY @27 /* You know, on a second thought - prepare to die! */ GOTO Demon013
IF~~THEN REPLY @28 /* I'm leaving. */ GOTO Demon014
IF~~THEN REPLY @29 /* Whatever. I need your help. I shall be back with the head. */ GOTO Demon015
END

IF~~THEN BEGIN Demon014
SAY @30 /* If you want to finish your current mission rapidly, you know the way to this room. */
IF~~THEN DO ~SetGlobal("WQxDemon","GLOBAL",1)~ EXIT
END

IF~~THEN BEGIN Demon015
SAY @31 /* You're smarter than I thought. */
IF~~THEN DO ~SetGlobal("WQxDemon","GLOBAL",1)~ EXIT
END

IF~~THEN BEGIN Demon013
SAY @32 /* The world won't collapse because of one Bhaalspawn's death. */
IF~~THEN DO ~Enemy()~ EXIT
END

//////Second Talk

IF~Global("WQxDemon","GLOBAL",2)~THEN BEGIN Demon200
SAY @33 /* So, it seams you're back. You have the head? */
IF~PartyHasItem("WQxHEAD")~THEN REPLY @34 /* Yes, here it is. Take it. */ GOTO Demon201
IF~~THEN REPLY @35 /* No, and you won't get it. Prepare to die! */ GOTO Demon202
IF~~THEN REPLY @36 /* No, but wait patiently and you shall get it. */ GOTO Demon203
END

IF~~THEN BEGIN Demon201
SAY @37 /* Ah, marvelous! Hahaha! And who's laughing now, mage? */
=
@38 /* So, Bhaalspawn, you shall get your reward! You provided my some entertainment, so. What you wish for? Gold? A magical weapon? Knowledge? I can give you those. */
IF~~THEN REPLY @39 /* I need money to get to my enemy - Irenicus. */ GOTO Demon204
IF~~THEN REPLY @40 /* The weapon sounds nice. I want it. */ GOTO Demon205
IF~~THEN REPLY @41 /* I want all the knowledge about the Spheres. */ GOTO Demon206
IF~~THEN REPLY @42 /* Hmm, I want something different. Teach me how to persuade people. */ GOTO Demon207
END

IF~~THEN BEGIN Demon204
SAY @43 /* Gold shall be yours, then! */
=
@44 /* And now I'm free! Hahaha! */
IF~~THEN DO ~SetGlobal("WQxDemon","GLOBAL",3) TakePartyItem("WQxHEAD") ReputationInc(-2) GiveGoldForce(15000) DestroySelf()~ EXIT
END

IF~~THEN BEGIN Demon205
SAY @45 /* Take it, then. It may look weak, but in good hands, it's a deadly tool. */
=
@46 /* And now excuse, me but I have some issues to solve! Hahaha! */
IF~~THEN DO ~SetGlobal("WQxDemon","GLOBAL",3) TakePartyItem("WQxHEAD") ReputationInc(-2) GiveItemCreate("WQxsl1",Player1,0,0,0)
 DestroySelf()~ EXIT
END

IF~~THEN BEGIN Demon206
SAY @47 /* You shall get it then. */
=
@48 /* Now I shall leave this filthy den! Hahaha! */
IF~~THEN DO ~SetGlobal("WQxDemon","GLOBAL",3) TakePartyItem("WQxHEAD") ReputationInc(-2) AddXPObject(Player1,25000) DestroySelf()~ EXIT
END

IF~~THEN BEGIN Demon207
SAY @49 /* Unusual reqeuest, but you'll get what you want! */
=
@50 /* Farewel, Bhaalspawn! Hahahaha! */
IF~~THEN DO ~SetGlobal("WQxDemon","GLOBAL",3) TakePartyItem("WQxHEAD") ReputationInc(-2) ApplySpell(Player1,GAIN_ONE_CHA_PERMANENT) DestroySelf()~ EXIT
END

IF~~THEN BEGIN Demon202
SAY @51 /* How foolish of you! */
IF~~THEN DO ~Enemy()~ EXIT
END

IF~~THEN BEGIN Demon203
SAY @52 /* Remember that demons aren't really patient. */
IF~~THEN EXIT
END