BEGIN WQxWIN

/////////1st talk

IF~Global("WQxWineQuest","GLOBAL",0)~THEN BEGIN WQxWIN000
SAY @0 /* What do you want? Can't you see I'm in despair? */
IF~~THEN REPLY @1 /* Indeed I do. That's why I'm interested. */ GOTO WQxWIN001
IF~~THEN REPLY @2 /* Exactly. That's why I decided I should talk to you. */ GOTO WQxWIN001
IF~~THEN REPLY @3 /* Sorry, I will leave you then. */ GOTO WQxWIN002
END

IF~~THEN BEGIN WQxWIN001
SAY @4 /* Oh. That was quite...straightforward. */
IF~~THEN REPLY @5 /* I am an adventurer. Do you possibly have some work? I really need some gold. */ GOTO WQxWIN003
IF~~THEN REPLY @6 /* I'm looking for some work. */ GOTO WQxWIN003
IF~~THEN REPLY @7 /* Indeed, I like to shock people. My work is done, then, so excuse me. */ GOTO WQxWIN002
END

IF~~THEN BEGIN WQxWIN003
SAY @8 /* Work, you say... */
=
@9 /* You see, I am a wine collector. I thought I would find something interesting here in Athkatla, but I am greatly disappointed. Nothing with fine color or of magnificent taste. */
=
@10 /* You need money? Fine! I can pay you one... no - one and a half thousand coins for a wine that can satisfy me! */
IF~~THEN REPLY @11 /* One and a half thousand for a bottle of wine?! Are you insane?! */ GOTO WQxWIN004
IF~~THEN REPLY @12 /* That sounds...interesting. */ GOTO WQxWIN004
IF~~THEN REPLY @13 /* I will think about it. Thanks for the offer. */ GOTO WQxWIN004
END

IF~~THEN BEGIN WQxWIN004
SAY @14 /* I don't want to go back home with empty hands! I want something SPLENDID. */
=
@15 /* But don't think I'll wait here for ages. You have - let's say... ten days! That's all time I can give you. I can't stand this cuisine and the dull wines of this city. */
IF~~THEN DO ~SetGlobal("WQxWineQuest","GLOBAL",1) SetGlobalTimer("WQxWineTime","GLOBAL",TEN_DAYS)~ EXIT
END

IF~~THEN BEGIN WQxWIN002
SAY @16 /* Pf! Do as you please, peasant. */
IF~~THEN EXIT
END

//////////2nd talk

IF~Global("WQxWineQuest","GLOBAL",2)~THEN BEGIN WQxWIN200
SAY @17 /* I hope you have something for me... */
IF~~THEN REPLY @18 /* No, not yet. */ GOTO WQxWIN201
IF~PartyHasItem("WQxWINE")~THEN REPLY @19 /* I have found this bottle. I'm not sure if the wine is fine, though... */ GOTO WQxWIN202
END

IF~~THEN BEGIN WQxWIN202
SAY @20 /* Give it to me! */
=
@21 /* Gods! Look at the color! Let me... ah, what a marvelous scent! I haven't seen something like that for years! That is surely good enough, I assure you. */
=
@22 /* Here is the reward. Take it and bother me no more with this dull face of yours. */
=
@23 /* Come, bottle. Let's go to papa's home! */
IF~~THEN DO ~SetGlobal("WQxWineQuest","GLOBAL",3) TakePartyItem("WQxWINE") GiveGoldForce(1500) EscapeArea()~ EXIT
END

IF~~THEN BEGIN WQxWIN201
SAY @24 /* So bother me not with your dog's breath! */
IF~~THEN EXIT
END