BEGIN WQxTRE

////FIRST TALK

IF~Global("WQxMainQuest","GLOBAL",0)~THEN BEGIN WRxTR01x00
SAY @0 /* Now, who are you?! You have flesh, you breath and you're not a woodworm, too! No sane person would visit these forsaken swamps. */
IF~~THEN REPLY @1 /* Certainly, I'm not a woodworm or any kind of undead. Mind me asking who *you* are? */ GOTO WRxTR01x01
IF~~THEN REPLY @2 /* You seem really surprised. I suppose you're not one of those creatures, too. */ GOTO WRxTR01x02
IF~~THEN REPLY @3 /* No, I'm not. Are you a woodworm? */ GOTO WRxTR01x03
END

IF~~THEN BEGIN WRxTR01x01
SAY @4 /* Gods, it's so good to meet living person in this damned place! */
IF~~THEN GOTO WRxTR01x04
END

IF~~THEN BEGIN WRxTR01x02
SAY @5 /* Obviously! */
IF~~THEN GOTO WRxTR01x04
END

IF~~THEN BEGIN WRxTR01x03
SAY @6 /* No, I'm not! How dare you?! Maybe we're in a bit of an extraordinary situation, but you should mind your manners! */
IF~~THEN GOTO WRxTR01x04
END

IF~~THEN BEGIN WRxTR01x04
SAY @7 /* My name is Vem Splinterbox and I used to live in this village. Well, I still do, but I had to live in the house outside. I guess I should leave this place for good, though. There's no way it could get back to normal. */
IF~~THEN REPLY @8 /* Tell me the whole story. I can't move on without some knowledge on it. */ GOTO WRxTR01x06
IF~~THEN REPLY @9 /* Maybe I would understand what you feel if I knew the story. */ GOTO WRxTR01x06
IF~~THEN REPLY @10 /* Don't bother me with the details of your accommodations. Tell me important facts. */ GOTO WRxTR01x05
END

IF~~THEN BEGIN WRxTR01x05
SAY @11 /* Fine, but I'd rather you change your tone. */
IF~~THEN GOTO WRxTR01x06
END

IF~~THEN BEGIN WRxTR01x06
SAY @12 /* So, let me start with the day our misfortune begun. */
=
@13 /* This place was never a joyful one, because of the dangerous creatures that live around. To make thing even worse, one cold and windy night, a man wearing white clothes arrived and met with our countess. From that time on, everything collapsed. */
=
@14 /* Our countess lost her mind and got obsessed with whiteness. I am sure it must have been influence of the man. I've heard people saying that he is a necromancer. */
=
@15 /* People started to disappear and the countess would never leave her palace. The only time we could see her were on nights of full moon when she would stand on the balcony above the entrance, and look at us without saying a single word. */
=
@16 /* At first we thought that the missing people were victims of a wild beast from the swamps, but later they didn't even try to hide their deeds. They killed people near the fountain at palace's entrance. She just looked at the people being killed and looked even better than before. And more pale. */
IF~~THEN REPLY @17 /* The necromancer must be using the people in a kind of ritual, I'm sure of it. */ GOTO WRxTR01x07
IF~~THEN REPLY @18 /* Do you think countess is a prisoner or a culprit? */ GOTO WRxTR01x08
END

IF~~THEN BEGIN WRxTR01x07
SAY @19 /* You're right and she enjoyed it. The necromancer announced that from now we shall call her The White Queen. She was the one who approved of his atrocities. */
IF~~THEN GOTO WRxTR01x09
END

IF~~THEN BEGIN WRxTR01x08
SAY @20 /* A culprit, obviously! Her servant, the necromancer, announced that from now on she should be called The White Queen. */
IF~~THEN GOTO WRxTR01x09
END

IF~~THEN BEGIN WRxTR01x09 
SAY @21 /* She must be stopped and I think I know the way! If no one helps me now, once she's done here she will become a threat to everyone near these swamps and maybe even beyond that. */
IF~~THEN REPLY @22 /* Speak then! I may help. */ GOTO WRxTR01x10
IF~~THEN REPLY @23 /* Well, I'm listening. */ GOTO WRxTR01x10
IF~~THEN REPLY @24 /* It's not working on me. I'm leaving and you should do the same. */ GOTO WRxTR01x11
END

IF~~THEN BEGIN WRxTR01x11
SAY @25 /* Wait! I... I'll tell you anyway. It's better to share this with someone instead of letting this knowledge die with me. */
=
@26 /* They are afraid of this tree! That's why I am safe here. I believe that this is the key to victory. Please, even if you're not going to help us, take this branch in case you meet her on the way out of the swamps - it may protect you. Also, keep away from the palace. There is some kind of barrier there - it may turn you or your allies into stone! */
=
@27 /* If you change your mind, please help me defeat those monsters! */
IF~~THEN DO ~SetGlobal("WQxMainQuest","GLOBAL",1) GiveItemCreate("WQxMain",Player1,0,0,0)~ EXIT
END

IF~~THEN BEGIN WRxTR01x10
SAY @28 /* Listen carefully. I think they are afraid of this tree. The Necromancer and the White Queen never comes near to it. They can't follow me to this hideout. I am sure you can use a branch of the tree somehow. */
=
@29 /* Here, take it. It can also protect you if you come too close to the palace - a kind of barrier is set up. Look out for it, it can turn you to stone. */
=
@30 /* If you have any more questions, feel free to ask. */
IF~~THEN REPLY @31 /* I will just go into the palace. No matter what it is, it must be stopped. */ DO ~SetGlobal("WQxMainQuest","GLOBAL",1) GiveItemCreate("WQxMain",Player1,0,0,0)~ GOTO WRxTR01x12
IF~~THEN REPLY @32 /* There is something I want to ask you about. */ DO ~SetGlobal("WQxMainQuest","GLOBAL",1) GiveItemCreate("WQxMain",Player1,0,0,0)~ GOTO WRxTR01x13
END

IF~~THEN BEGIN WRxTR01x13
SAY @33 /* You do? */
IF~~THEN GOTO WRxTR01xQ0
END

IF~~THEN BEGIN WRxTR01x12
SAY @34 /* You're right. If you have any questions, do visit me. I'm not going anywhere. */
IF~~THEN EXIT
END

////QUESTIONS

IF~GlobalGT("WQxMainQuest","GLOBAL",0) !Global("WQxMainQuest","GLOBAL",11)~THEN BEGIN WRxTR01xQ0
SAY @35 /* Yes? I'm listening carefully. */
IF~~THEN REPLY @36 /* How do you know that the man in white was a necromancer? */ GOTO WRxTR01xQ1
IF~Global("WQxName","GLOBAL",0)~THEN REPLY @37 /* What's the real name of White Queen? */ DO ~SetGlobal("WQxName","GLOBAL",1)~ GOTO WRxTR01xQ2
IF~~THEN REPLY @38 /* Do you have any idea why they can't do a thing to this tree? */ GOTO WRxTR01xQ3
IF~~THEN REPLY @39 /* Why didn't you run away from the village when you had time? */ GOTO WRxTR01xQ4
IF~~THEN REPLY @40 /* How could you live here for so many years? */ GOTO WRxTR01xQ5
IF~~THEN REPLY @41 /* You mentioned some kind of barrier, didn't you? */ GOTO WRxTR01xQ6
IF~~THEN REPLY @42 /* I should go now. */ GOTO WRxTR01xQ7
END 

IF~~THEN BEGIN WRxTR01xQ1
SAY @43 /* Didn't you listen to me? He made all those... strange things! The ritual or something. He even set up this strange barrier around the palace! */
=
@44 /* No doubt about it. He is a necromancer, I am sure of it. Do you have any other questions? */
IF~~THEN REPLY @45 /* Indeed, I do. */ GOTO WRxTR01xQ0
IF~~THEN REPLY @46 /* No, I should move on before something bad happens. */ GOTO WRxTR01x12
END

IF~~THEN BEGIN WRxTR01xQ2
SAY @47 /* Celine Shalloweye, but it doesn't matter. She has changed - she's the White Queen now. */
=
@48 /* I don't think this can help you, anyway. Maybe there's something else you want to ask about? */
IF~~THEN REPLY @49 /* Hmm, I may have another question. */ GOTO WRxTR01xQ0
IF~~THEN REPLY @50 /* No, now it's time for some action. */ GOTO WRxTR01x12
END

IF~~THEN BEGIN WRxTR01xQ3
SAY @51 /* Yes, actually. I've seen some symbols on the tree, some looked like scales - the symbol of Kelemvor! I think this place was once consecrated by a Doomguide of Kelemvor or at least some kind of cultist. I'm not sure how long the blessing will protect this tree, though. */
=
@52 /* Do you have any other questions? */
IF~~THEN REPLY @53 /* I may have another one. */ GOTO WRxTR01xQ0
IF~~THEN REPLY @54 /* No, and by the way, I suppose you should rest a bit. You look pale. */ GOTO WRxTR01x12
END

IF~~THEN BEGIN WRxTR01xQ4
SAY @55 /* I did, but I had hoped that the White Queen can be stopped. I've studied how those creatures behave, I've observed. I've even tried to ask some people to help, but they didn't want to listen. */
=
@56 /* One night, when I was observing them, they realized my presence so I ran towards this tree. I'm safe here, I suppose, but I'm not sure that they won't come here as well, one day. */
IF~~THEN REPLY @57 /* I have another question. */ GOTO WRxTR01xQ0
IF~~THEN REPLY @58 /* Thank you. I should go now. */ GOTO WRxTR01x12
END

IF~~THEN BEGIN WRxTR01xQ5
SAY @59 /* I do leave this place from time to time to get food, but I do come back. I believe that this nightmare will end. It simply... must end. */
IF~~THEN REPLY @60 /* I see. Let me ask another question. */ GOTO WRxTR01xQ0
IF~~THEN REPLY @61 /* Do as you please, but it's not a good idea to stay here. Now I'm leaving. You're going to stay anyway, yes? */ GOTO WRxTR01x12
END

IF~~THEN BEGIN WRxTR01xQ6
SAY @62 /* Yes. */
=
@63 /* Some time after necromancer came into the palace, he set up some kind of barrier that transforms every one who doesn't follow the White Queen into stone. */
=
@64 /* That must be a horrible death... */
IF~~THEN REPLY @65 /* Probably, but there's more I would like to ask. */ GOTO WRxTR01xQ0
IF~~THEN REPLY @66 /* At least they don't suffer for long. I should go now. */ GOTO WRxTR01x12
END

IF~~THEN BEGIN WRxTR01xQ7
SAY @67 /* Goodbye then. If you have any other questions, I shall be waiting here. */
IF~~THEN EXIT
END 

///////DruidEnd

IF~Global("WQxMainQuest","GLOBAL",11)~THEN BEGIN WQxTreeEnd000
SAY @68 /* Ha! You've done it! The White Queen is dead at last! */
=
@69 /* At least she got a proper end she deserves! I've told her from very beginning that she can't win this war. Now I can leave this condemned place. */
IF~~THEN REPLY @70 /* You used us! The White Queen told us the whole story. */ GOTO WQxTreeEnd001
IF~~THEN REPLY @71 /* You stayed here just because you wanted her to die first? You're the true monster here. */ GOTO WQxTreeEnd002
IF~~THEN REPLY @72 /* You managed to trick us into defeating the Queen. Quite intelligent. */ GOTO WQxTreeEnd003
END

IF~~THEN BEGIN WQxTreeEnd001
SAY @73 /* So you should understand that it was her own fault. She let the Gardenwest family die. */
IF~~THEN GOTO WQxTreeEnd004
END

IF~~THEN BEGIN WQxTreeEnd002
SAY @74 /* I wanted to avenge the Gardenwest family. They all died because of her. */
IF~~THEN GOTO WQxTreeEnd004
END

IF~~THEN BEGIN WQxTreeEnd003
SAY @75 /* I had to find a way to avenge the Gardenwest family. He and his family died because of her. */
IF~~THEN GOTO WQxTreeEnd004
END

IF~~THEN BEGIN WQxTreeEnd004
SAY @76 /* What would you do? He was like a brother to me! I was like a part of his family. I can say that I loved him - the way you love your brother. She took all of them from me just because she was too busy to realize his family's situation. */
IF~~THEN REPLY @77 /* You just want to find an excuse for your actions, druid. */ GOTO WQxTreeEnd005
IF~~THEN REPLY @78 /* So? Is that a reason to destroy the whole village? Don't make me laugh. */ GOTO WQxTreeEnd006
IF~~THEN REPLY @79 /* I would do the same. Get out of my sight before I change my mind. */ GOTO WQxTreeEnd007
IF~~THEN REPLY @80 /* You killed an innocent child! */ GOTO WQxTreeEnd006
END

IF~~THEN BEGIN WQxTreeEnd005
SAY @81 /* Believe me or not. I don't care. */
IF~~THEN GOTO WQxTreeEnd008
END

IF~~THEN BEGIN WQxTreeEnd006
SAY @82 /* Revolution always has some kind of sacrifice. */
IF~~THEN GOTO WQxTreeEnd008
END

IF~~THEN BEGIN WQxTreeEnd008
SAY @83 /* Don't you understand? I did it for all of them. If I was the one who ruled this village, I would never have let this happen. I didn't know she would bring her brother to this place. He killed them and I didn't want their sacrifices to be wasted. */
IF~~THEN REPLY @84 /* That's how you would rule this place? "I didn't know her ally would come"? She was much better ruler than you would be. */ GOTO WQxTreeEnd009
IF~~THEN REPLY @85 /* You are cruel. All those lives were wasted on your own revolution! It is you who killed them! */ GOTO WQxTreeEnd009
IF~~THEN REPLY @86 /* I understand. You couldn't know he would come. You're free, but I if I were you, I'd leave this place before I change my mind. */ GOTO WQxTreeEnd007
END

IF~~THEN BEGIN WQxTreeEnd009
SAY @87 /* Take those words back. I did what I believed in. */
IF~~THEN REPLY @88 /* No. */ GOTO WQxTreeEnd010
IF~~THEN REPLY @89 /* Oh, so you believe in sacrificing children to hags? Your mother must be proud of you. */ GOTO WQxTreeEnd010
IF~~THEN REPLY @90 /* Just get out of my sight. I won't kill you, but I don't want to see your face. Ever. */ GOTO WQxTreeEnd007
END

IF~~THEN BEGIN WQxTreeEnd010
SAY @91 /* I repeat - renege those words. */
IF~~THEN REPLY @92 /* No! */ GOTO WQxTreeEnd011
IF~~THEN REPLY @93 /* Just get out of my sight. */ GOTO WQxTreeEnd007
END

IF~~THEN BEGIN WQxTreeEnd011
SAY @94 /* You are as foolish as Queen was! You shall join her in death! */
=
@95 /* Shaneelah! I call thee, hag! */
=
@96 /* *I call thee*! */
=
@97 /* Shaneelah, you traitor! */
=
@98 /* I don't need her help. I can still call creatures of the swamps myself. Prepare to die! */
IF~~THEN DO ~SetGlobal("WQxMainQuest","GLOBAL",12) Enemy()~ EXIT
END

IF~~THEN BEGIN WQxTreeEnd007
SAY @99 /* Thank you. You will never see me again. Take this book as a gift. */
=
@100 /* Farewell. */
IF~~THEN DO ~SetGlobal("WQxMainQuest","GLOBAL",20) EscapeArea()~ EXIT
END