BEGIN WQxST

IF~Global("WQxSlaveTalk","GLOBAL",0)~THEN BEGIN WQxSP000
SAY @0 /* Please, don't kill me! I don't want to die! */
IF~~THEN REPLY @1 /* So maybe you'll tell me what's going on here? I may consider letting you go, then. */ GOTO WQxSP001
IF~~THEN REPLY @2 /* Tell me everything about this madness here! Now! */ GOTO WQxSP001
IF~~THEN REPLY @3 /* Just get out of my sight. */ GOTO WQxSP002
IF~~THEN REPLY @4 /* No. You will alert the others. Prepare to die. */ GOTO WQxSP003
END

IF~~THEN BEGIN WQxSP001
SAY @5 /* I'll tell you! I'll tell you everything I know! */
IF~~THEN REPLY @6 /* Go on then. */ GOTO WQxSP004
IF~~THEN REPLY @7 /* Hmm, it was nice to see you believe you'll survive, but I don't need your help. Prepare to die. */ GOTO WQxSP003
END

IF~~THEN BEGIN WQxSP004
SAY @8 /* You know Master Shalloweye, don't you? Queen sent for him because something...something happened. She was both furious and desperate. I'm not sure what exactly happened, because I came here with master. I'm not allowed to ask questions and I didn't want to disobey master... please believe me! */
=
@9 /* I think Queen...lost something. Something precious. That's all I know! I swear! I'm just a simple servent! They don't tell me anything! */
IF~~THEN REPLY @10 /* Are you sure this is everything? */ GOTO WQxSP005
IF~~THEN REPLY @11 /* If you're a servant here you must know where is the Queen and what is behind these doors. */ GOTO WQxSP006
IF~~THEN REPLY @12 /* You may go. */ GOTO WQxSP002
IF~~THEN REPLY @13 /* Sorry, but I can't let you go. You shall pay for working with those monsters. */ GOTO WQxSP003
END

IF~~THEN BEGIN WQxSP005
SAY @14 /* Yes! I swear! */
IF~~THEN REPLY @15 /* Good. If you're a servant here you must know where is the Queen and what is behind these doors? */ GOTO WQxSP006
IF~~THEN REPLY @16 /* Fine. You may go. */ GOTO WQxSP002
IF~~THEN REPLY @17 /* Now you shall pay for working with those monsters. */ GOTO WQxSP003
END

IF~~THEN BEGIN WQxSP006
SAY @18 /* The prison level is down here! The Queen is on the top level of a tower. The entrance is up from here, near the black and white signs. But look out, there is a trap, so make sure you take care of it first! */
IF~~THEN REPLY @19 /* You did well. You may leave now. */ GOTO WQxSP002
IF~~THEN REPLY @20 /* That's all I need. Now, prepare to die. */ GOTO WQxSP003
END

IF~~THEN BEGIN WQxSP002
SAY @21 /* Thank you! I should have left this place a long time ago! */
IF~~THEN DO ~SetGlobal("WQxSlaveTalk","GLOBAL",1) AddexperienceParty(6000) EscapeArea()~ EXIT
END

IF~~THEN BEGIN WQxSP003
SAY @22 /* Aaaa! */
IF~~THEN DO ~SetGlobal("WQxSlaveTalk","GLOBAL",1) Enemy()~ EXIT
END

